Chiaki4Deck PKGBUILD

README.md

moved

PKGBUILD

# based on https://aur.archlinux.org/cgit/aur.git/tree/PKGBUILD?h=chiaki-git
pkgname=chiaki4deck-git
_gitname=chiaki4deck
pkgver=1.3.0
pkgrel=1
pkgdesc="Unofficial PlayStation 4 remote play client"
arch=(x86_64)
url="https://github.com/streetpea/chiaki4deck"
license=('AGPL3')
depends=('qt5-base' 'qt5-multimedia' 'qt5-svg' 'sdl2' 'opus' 'ffmpeg' 'openssl' 'gcc-libs' 'fftw')
makedepends=('git' 'cmake' 'python-protobuf' 'libva' 'python-setuptools')
optdepends=(
            'intel-media-driver: vaapi backend for Intel GPUs [>= Broadwell]'
            'libva-intel-driver: vaapi backend for Intel GPUs [<= Haswell]'
            'libva-vdpau-driver: vaapi backend for Nvidia and AMD GPUs'
            'libva-mesa-driver: alternative vaapi backend for AMD GPUs'
           )
provides=('chiaki')
conflicts=('chiaki')
source=(git+"${url}")
md5sums=("SKIP")

pkgver() {
  cd ${_gitname}
  git describe --long --tags | sed 's:^v::;s:\([^-]*-g\):r\1:;s:-:.:g'
}

prepare() {
  cd ${_gitname}
  mkdir build
  git submodule update --init
}

build() {
  cd ${_gitname}/build
  cmake .. -DCMAKE_INSTALL_PREFIX="/usr" -DCMAKE_BUILD_TYPE="Release"
  make -j
}

package() {
  cd ${_gitname}/build
  make -j DESTDIR="${pkgdir}" install
  install -dm755 "${pkgdir}/usr/share/licenses/${pkgname}/"
  for lic in ../LICENSES/*; do
    install -m644 ${lic} "${pkgdir}/usr/share/licenses/${pkgname}/${lic##*/}"
  done
}

Yes I was able to download but not sure I’m extracting right or extracting in the correct place.

…

On Wed, Nov 29, 2023 at 3:49 AM Thiago Vidal ***@***.***> wrote: ***@***.**** commented on this gist. ------------------------------ ive tried to follow the readme but i have no idea how to set this up. Can you please explain No problem, how far were you able to get? Were you able to download and extract the files? — Reply to this email directly, view it on GitHub <https://gist.github.com/tvidal-net/dda93291eb5898d43ae268e063c928be#gistcomment-4776222> or unsubscribe <https://github.com/notifications/unsubscribe-auth/BEKL7IPA2QWABOOEOX47TGLYG4AIXBFKMF2HI4TJMJ2XIZLTSKBKK5TBNR2WLJDHNFZXJJDOMFWWLK3UNBZGKYLEL52HS4DFQKSXMYLMOVS2I5DSOVS2I3TBNVS3W5DIOJSWCZC7OBQXE5DJMNUXAYLOORPWCY3UNF3GS5DZVRZXKYTKMVRXIX3UPFYGLK2HNFZXIQ3PNVWWK3TUUZ2G64DJMNZZDAVEOR4XAZNEM5UXG5FFOZQWY5LFVEYTEMBTGIZTMOJTU52HE2LHM5SXFJTDOJSWC5DF> . You are receiving this email because you commented on the thread. Triage notifications on the go with GitHub Mobile for iOS <https://apps.apple.com/app/apple-store/id1477376905?ct=notification-email&mt=8&pt=524675> or Android <https://play.google.com/store/apps/details?id=com.github.android&referrer=utm_campaign%3Dnotification-email%26utm_medium%3Demail%26utm_source%3Dgithub> .