Create font tables within gnuplot using the example of typical LaTeX fonts

gistfile1.txt

set terminal postscript enhanced eps dashed color "NimbusRomNo9L-Regu" 17 fontfile '/usr/share/texmf-texlive/fonts/type1/public/txfonts/txsy.pfb' fontfile '/usr/share/texmf-texlive/fonts/type1/public/txfonts/rtxmi.pfb'

set xrange [0:1]
set yrange [0:1]
set lmargin 0
set tmargin 0
set bmargin 0
set rmargin 0
unset xtics
unset ytics
unset key
unset border

set output "symbols_NimbusRomNo9L.eps"
set label 1000 at screen 0.05,(1-0.08) "NimbusRomNo9L Font"
do for [i=0:255] {
  set label i+1 at screen 0.05+(1.0/14.0)*floor(i/20),1-(0.15+1.0/25.0*(i%20)) sprintf("%i %c",i,i)
}
plot -1 lw 0


set output "symbols_txsy.eps"
set label 1000 at screen 0.05,(1-0.08) "txsy Font"
do for [i=0:127] {
	set label i+1 at screen 0.05+(1.0/14.0)*floor(i/20),1-(0.15+1.0/25.0*(i%20)) sprintf("%i {/txsy %c}",i,i)
}
plot -1 lw 0

set output "symbols_rtxmi.eps"
set label 1000 at screen 0.05,(1-0.08) "rtxmi Font"
do for [i=0:127] {
	set label i+1 at screen 0.05+(1.0/14.0)*floor(i/20),1-(0.15+1.0/25.0*(i%20)) sprintf("%i {/rtxmi %c}",i,i)
}
plot -1 lw 0