Create a gist now

Instantly share code, notes, and snippets.

@udawtr /wget.vbs
Last active Nov 13, 2017

What would you like to do?
wget.vbs - similar to wget but written in vbscript
'wget.vbs - similar to wget but written in vbscript
'based on a script by Chrissy LeMaire
' Usage
if WScript.Arguments.Count < 1 then
MsgBox "Usage: wget.vbs <url> (file)"
WScript.Quit
end if
' Arguments
URL = WScript.Arguments(0)
if WScript.Arguments.Count > 1 then
saveTo = WScript.Arguments(1)
else
parts = split(url,"/")
saveTo = parts(ubound(parts))
end if
' Fetch the file
Set objXMLHTTP = CreateObject("MSXML2.ServerXMLHTTP")
objXMLHTTP.open "GET", URL, false
objXMLHTTP.send()
If objXMLHTTP.Status = 200 Then
Set objADOStream = CreateObject("ADODB.Stream")
objADOStream.Open
objADOStream.Type = 1 'adTypeBinary
objADOStream.Write objXMLHTTP.ResponseBody
objADOStream.Position = 0 'Set the stream position to the start
Set objFSO = Createobject("Scripting.FileSystemObject")
If objFSO.Fileexists(saveTo) Then objFSO.DeleteFile saveTo
Set objFSO = Nothing
objADOStream.SaveToFile saveTo
objADOStream.Close
Set objADOStream = Nothing
End if
Set objXMLHTTP = Nothing
' Done
WScript.Quit
@MalikKillian

This comment has been minimized.

Show comment Hide comment
@MalikKillian

MalikKillian Jul 3, 2013

MSXML2.ServerXMLHTTP can be used in place of MSXML2.XMLHTTP if you encounter "Access is denied" errors.

MSXML2.ServerXMLHTTP can be used in place of MSXML2.XMLHTTP if you encounter "Access is denied" errors.

@udawtr

This comment has been minimized.

Show comment Hide comment
@udawtr

udawtr Nov 28, 2013

@MalikKillian
Thanks. Your comment is very useful to me.

Owner

udawtr commented Nov 28, 2013

@MalikKillian
Thanks. Your comment is very useful to me.

@Abhinav-Biswas

This comment has been minimized.

Show comment Hide comment
@Abhinav-Biswas

Abhinav-Biswas Jul 7, 2015

how to provide proxy server details (host/username/password) in this script?

how to provide proxy server details (host/username/password) in this script?

@bitnetwork

This comment has been minimized.

Show comment Hide comment
@bitnetwork

bitnetwork Apr 2, 2016

For you jscripties out there, I optimized this for jscript here: https://gist.github.com/BitNetwork/b6f7ef23fac1044e5dfb1187fd1936af

For you jscripties out there, I optimized this for jscript here: https://gist.github.com/BitNetwork/b6f7ef23fac1044e5dfb1187fd1936af

@OdeV66

This comment has been minimized.

Show comment Hide comment
@OdeV66

OdeV66 Nov 13, 2017

Hi, when running the VBS I'm getting 'Invalid URL', while in fact, it isn't? Literally copying that into the browser does get me to that file/page.
Any ideas please?
image

OdeV66 commented Nov 13, 2017

Hi, when running the VBS I'm getting 'Invalid URL', while in fact, it isn't? Literally copying that into the browser does get me to that file/page.
Any ideas please?
image

Sign up for free to join this conversation on GitHub. Already have an account? Sign in to comment