Basic get/delete/put/post json store example using Perl 6 and Cro

json-resource-service.pl6

#!/usr/bin/env perl6

use v6;
use Cro::HTTP::Server;
use Cro::HTTP::Router;
use Cro::HTTP::BodyParser;

# Create a new resource
# curl --verbose -H "Content-Type: application/json" -X POST -d '{ "foo" : "123" }' http://localhost:3000/resource

# Get list of all resources
# curl --verbose -X GET http://localhost:3000/resource

# Update an existing resource
# curl --verbose -H "Content-Type: application/json" -X PUT -d '{ "bar" : "456" }' http://localhost:3000/resource/0

# Delete an existing resource
# curl --verbose -X DELETE http://localhost:3000/resource/0

sub MAIN(:$host = 'localhost', :$port = 3000) {
    my $json-storage-service = Cro::HTTP::Server.new(
        host         => $host,
        port         => $port,
        body-parsers => [Cro::HTTP::BodyParser::JSON],
        application  => route {
            my Hash @storage;
            my atomicint $storage-counter = 0;
            my subset ValidResourceId of Int where { @storage[$_].defined }

            get -> 'resource', ValidResourceId $id {
                content 'application/json', @storage[$id];
            }

            get -> 'resource' {
                content 'application/json', @storage.grep(*.defined).list;
            }

            put -> 'resource', ValidResourceId $id {
                request-body -> %json where !*.?EXISTS-KEY('_id') {
                    @storage[$id]   = %json;
                    response.status = 204;
                }
            }

            post -> 'resource' {
                request-body -> %json where !*.?EXISTS-KEY('_id') {
                    my $resource-id        = $storage-counter⚛++;
                    @storage[$resource-id] = %( %json.Slip, _id => $resource-id );
                    created "/resource/$resource-id", 'application/json', %json;
                }
            }

            delete -> 'resource', ValidResourceId $id {
                @storage[$id]   = Nil;
                response.status = 204;
            }
        },
    ) andthen *.start;

    react {
        whenever signal(SIGINT) {
            $json-storage-service.stop;
            exit;
        }
    }
}

BEGIN die "Run `zef install Cro --/test` first\n" if (try require ::("Cro::HTTP::Server")) ~~ Nil;