CURFS.pm6

    proto method candidates(|) {*}
    multi method candidates(Str:D $name, :$auth, :$ver, :$api) {
        return samewith(CompUnit::DependencySpecification.new(
            short-name      => $name,
            auth-matcher    => $auth // True,
            version-matcher => $ver  // True,
            api-matcher     => $api  // True,
        ));
    }
    multi method candidates(CompUnit::DependencySpecification $spec) {
        return Empty unless $spec.from eq 'Perl6';

        $!distribution = $!prefix.add('META6.json').f
            ?? Distribution::Path.new($!prefix)
            !! Distribution::Hash.new({
                    name  => $spec.short-name,
                    ver   => Version.new(0),
                    api   => Version.new(0),
                    auth  => '',
                    files => ($spec.short-name.contains('/')
                        ?? %( $spec.short-name => $spec.short-name )
                        !! %( )),
                    provides => ($spec.short-name.contains('/')
                        ?? %( )
                        !! %( $spec.short-name => first *,
                                grep { $!prefix.child($_).f },
                                map  { $spec.short-name.subst(:g, "::", $*SPEC.dir-sep) ~ ".$_" },
                                @extensions) ),
                }, :$!prefix);

        my $version-matcher = ($spec.version-matcher ~~ Bool)
            ?? $spec.version-matcher # fast path for matching Version.new(*)
            !! Version.new($spec.version-matcher);
        my $api-matcher = ($spec.api-matcher ~~ Bool)
            ?? $spec.api-matcher
            !! Version.new($spec.api-matcher);

        return False unless $!distribution.meta<auth> ~~ $spec.auth-matcher
            and Version.new($!distribution.meta<ver>) ~~ $version-matcher
            and Version.new($!distribution.meta<api>) ~~ $api-matcher;

        $!distribution;
    }