mirc auto invite

mirc auto invite

;File name: Auto invite on join, on part and on kick.
;Written By: JOMARO
;E-mail: jomaro@zdnetmail.com
;Website: http://welcome.to/jomaro
;============================
;===Auto Invite Dialog===>
dialog inv {
  title "Auto Invite v1.0"
  size -1 -1 500 183
  box "Auto Invite", 1, 10 5 480 140, right
  check "On Join", 3, 20 31 60 15, right
  text "Invite From: (# OR #name OR #n1,#n2,..)", 4, 100 15 200 15, left
  edit "", 5, 100 28 230 22, left, autohs
  text "Invite To:", 6, 340 15 50 15, left
  edit "", 7, 340 28 140 22, left, autohs
  check "On Part", 8, 20 71 60 15, right
  text "Invite From: (# OR #name OR #n1,#n2,..)", 9, 100 55 200 15
  edit "", 10, 100 69 230 22, left, autohs
  text "Invite To:", 11, 340 55 50 15, left
  edit "", 12, 340 69 140 22, left, autohs
  check "On Kick", 13, 20 111 60 15, right
  text "Invite From: (# OR #name OR #n1,#n2,..)", 14, 100 95 200 15, left
  edit "", 15, 100 110 230 22, left, autohs
  text "Invite To:", 16, 340 95 50 15, left
  edit "", 17, 340 110 140 22, left, autohs
  button "OK", 18, 150 150 60 30, OK
  button "Reset", 19, 210 150 60 30
  button "Cancel", 20, 270 150 60 30, cancel
}
on *:dialog:inv:init:0:{ 
  if ($group(#on-join-invite) == on) { did -c inv 3 | did -a inv 5 %invite-fromj | did -a inv 7 %invite-toj | did -e inv 5 | did -e inv 7 } | else { did -a inv 5 %invite-fromj | did -a inv 7 %invite-toj | did -b inv 5 | did -b inv 7 }
  if ($group(#on-part-invite) == on) { did -c inv 8 | did -a inv 10 %invite-fromp | did -a inv 12 %invite-top | did -e inv 10 | did -e inv 12 } | else { did -a inv 10 %invite-fromp | did -a inv 12 %invite-top | did -b inv 10 | did -b inv 12 }
  if ($group(#on-kick-invite) == on) { did -c inv 13 | did -a inv 15 %invite-fromk | did -a inv 17 %invite-tok | did -e inv 15 | did -e inv 17 } | else { did -a inv 15 %invite-fromk | did -a inv 17 %invite-tok | did -b inv 15 | did -b inv 17 }
}
on *:dialog:inv:sclick:*:{
  if ($did == 3) && ($did(3).state == 1) { did -e inv 5 | did -e inv 7 } | elseif ($did == 3) { did -b inv 5 | did -b inv 7 }
  if ($did == 8) && ($did(8).state == 1) { did -e inv 10 | did -e inv 12 } | elseif ($did == 8) { did -b inv 10 | did -b inv 12 }
  if ($did == 13) && ($did(13).state == 1) { did -e inv 15 | did -e inv 17 } | elseif ($did == 13) { did -b inv 15 | did -b inv 17 }
  if ($did = 18) {
    if ($did(3).state == 1) { .enable #on-join-invite | .disable #on-join-notice #on-join-msg | set %invite-fromj $did(5).text | set %invite-toj $did(7).text } | else { .disable #on-join-invite }
    if ($did(8).state == 1) { .enable #on-part-invite | .disable #on-part-notice #on-part-msg | set %invite-fromp $did(10).text | set %invite-top $did(12).text } | else { .disable #on-part-invite }
    if ($did(13).state == 1) { .enable #on-kick-invite | .disable #on-kick-notice #on-kick-msg | set %invite-fromk $did(15).text | set %invite-tok $did(17).text } | else { .disable #on-kick-invite }
    if ($did(5).text == $null) && ($did(7).text == $null) { .disable #on-join-invite | unset %invite-fromj %invite-toj }
    if ($did(10).text == $null) && ($did(12).text == $null) { .disable #on-part-invite | unset %invite-fromp %invite-top }
    if ($did(15).text == $null) && ($did(17).text == $null) { .disable #on-kick-invite | unset %invite-tok %invite-fromk }
  }
  if ($did == 19) { if ($did(3).state == 1) { did -r inv 5 | did -r inv 7 | unset %invite-fromj %invite-toj } | if ($did(8).state == 1) { did -r inv 10 | did -r inv 12 | unset %invite-fromp %invite-top } | if ($did(13).state == 1) { did -r inv 15 | did -r inv 17 | unset %invite-fromk %invite-tok } }
}
alias inv dialog -mok inv inv

#on-join-invite off
on *:JOIN:%invite-fromj:if ($nick != $me) { invite $nick %invite-toj }
#on-join-invite End

#on-part-invite off
on *:PART:%invite-fromp:if ($nick != $me) { invite $nick %invite-top }
#on-part-invite End

#on-kick-invite off
on *:KICK:%invite-fromk:if ($knick != $me) { invite $knick %invite-tok }
#on-kick-invite End

menu channel,menubar,status {
  Auto Invite:/inv
}
alias thank dialog -mo thank thank
dialog thank {
  title "Add-ons By Jomaro 2000"
  size -1 -1 200 180
  box "",1,5 0 190 70
  text "Thank you for loading this Add-on written by jomaro. Please visit my website for more add-ons and other IRC tools. Have fun.",2,10 12 180 50,left
  box "",3,5 68 190 86
  text "jomaro@zdnetmail.com",4,10 80 180 15,center
  edit "http://welcome.to/jomaro",5,33 100 130 22,center,read
  button "Visit",6,70 127 50 20
  button "Close",7,5 158 190 20,ok
}
on *:dialog:thank:init:0:/did -f thank 6
on *:dialog:thank:sclick:6:/run http://welcome.to/jomaro
on *:load:if ($version < 5.51) { echo 3 *** Warning: This script requires mIRC v5.51 or higher. You are using mIRC $version which is incompatible with this script. Please download the latest copy of mIRC from www.mirc.co.uk | .unload -rs autoinvite.mrc | halt } | thank