Implement Visit using phantom types and smart constructors

PhantomVisit.hs

module PhantomVisit (
    Visit,
    CallAhead,
    Remote,
    WalkIn,
    Rsv,
    callAhead,
    remote,
    walkIn,
    rsv
) where
    
import Data.Time

data CallAhead
data Remote
data WalkIn
data Rsv

data Visit t = Visit {
        partySize :: Int,
        enqueuedAt :: UTCTime,
        quotedWait :: NominalDiffTime,
        reservedAt :: Maybe UTCTime
    }
    deriving (Eq, Show)
    
rsv :: Int -> UTCTime -> NominalDiffTime -> UTCTime -> Visit Rsv
rsv ps time qw ra = Visit ps time qw (Just ra)

walkIn :: Int -> UTCTime -> NominalDiffTime -> Visit WalkIn
walkIn ps time qw = Visit ps time qw Nothing

callAhead :: Int -> UTCTime -> NominalDiffTime -> Visit CallAhead
callAhead ps time qw = Visit ps time qw Nothing

remote :: Int -> UTCTime -> NominalDiffTime -> Visit Remote
remote ps time qw = Visit ps time qw Nothing

-- serious oversimplification :)
calcWait :: Visit a -> NominalDiffTime
calcWait v = case reservedAt v of
    Nothing -> quotedWait v
    Just _  -> 0

zzz_interactive

t <- getCurrentTime
let v1 = rsv 3 t (fromIntegral 3) t
let v2 = walkIn 3 t (fromIntegral 3)

calcWait v1
> 0s

calcWait v2
> 3s