default.nix

let
  pkgsOrig = import <nixpkgs> {};
  pkgsMusl = pkgsOrig.pkgsMusl;
  extraLibraries = with pkgsMusl; [
    musl
    zlib zlib.static
    libffi (libffi.override { stdenv = makeStaticLibraries stdenv; })
    gmp (gmp.override { withStatic = true; })
  ];
  docker =
    let layered = pkgsOrig.dockerTools.buildLayeredImage {
      name = "dd-base";
      tag = "latest";
      contents = [
        pkgsMusl.stdenv.cc.bintools
        pkgsMusl.stdenv.cc
        pkgsMusl.bash
        pkgsMusl.coreutils
        pkgsMusl.pkgconfig
      ] ++ extraLibraries;
    };
    in pkgsOrig.dockerTools.buildImage {
      name = "dd";
      tag = "latest";
      fromImage = layered;
      runAsRoot = ''
        #!${pkgsMusl.stdenv.shell}
        ${pkgsMusl.dockerTools.shadowSetup}
        mkdir /tmp
      '';
      diskSize = 8192;
      config = {
        Cmd = [ "${pkgsMusl.bash}/bin/sh" ];
        Env = [
          "PATH=/bin"
          "LD_LIBRARY_PATH=${pkgsMusl.stdenv.lib.makeLibraryPath extraLibraries}"
          "C_INCLUDE_PATH=${pkgsMusl.stdenv.lib.makeSearchPathOutput "dev" "include" extraLibraries}"
        ];
      };
    };
in docker