Vertical text on NVL mode

gistfile1.txt

########## script.rpy ##########
init python:

    style.default.font = "YOzRN.TTC"
    style.default.language = "eastasian"

    style.nvl_menu_choice_button.top_margin = 20

    style.nvl_window.background = "nvl_window.png"
    style.nvl_window.xpadding = 55
    style.nvl_window.ypadding = 55
    narator = Character(None, color="#6666ff", kind=nvl)
    menu = nvl_menu

label start:
    narator "どっちの箱にする？"
    menu:
        "「右！」":
            narator "「うーん、右！」"
        "「左！」":
            narator "「うーん、左！」"
    narator "「残念、はずれでしたー」"
    narator "「まさか両方はずれってことはないよな？」"
    narator "「どっちもはずれでしたー！」"

########## screens.rpy ##########

screen nvl:

    window:
        style "nvl_window"
        xmaximum 800
        ymaximum 600

        has hbox:
            style "nvl_hbox"
            box_reverse True
            xalign 1.0

        # Display dialogue.
        for who, what, who_id, what_id, window_id in dialogue:
            window:
                id window_id

                has vbox:
                    spacing 10
                    xalign 1.0

                if who is not None:
                    text who id who_id vertical True xalign 1.0

                text what id what_id vertical True

        # Display a menu, if given.
        if items:
            hbox:
                box_reverse True
                id "menu"
                for caption, action, chosen in items:
                    if action:
                        button:
                            style "nvl_menu_choice_button"
                            action action
                            xfill False yfill True xmargin 0
                            text caption style "nvl_menu_choice" vertical True
                    else:
                        text caption style "nvl_dialogue" vertical True