facter_seetings.pp

class puppet_bootstrap::facter (
  Optional[Array[String]] $blocklist = undef,
  Optional[Array[String]] $cachelist = undef,
  String $cache_ttl = '1 day',
) {
  # individual facts can only be blocklisted in puppet 7
  if versioncmp(fact('aio_agent_version'),'7') >= 0 {
    file { '/etc/puppetlabs/facter':
      ensure => directory,
    }

    Hocon_setting {
      path    => '/etc/puppetlabs/facter/facter.conf',
      require => File['/etc/puppetlabs/facter'],
    }

    if $blocklist {
      hocon_setting { 'blocklist facts group':
        ensure  => present,
        setting => 'fact-groups.blocked-facts',
        value   => $blocklist,
        type    => 'array',
      }
      -> hocon_setting { 'blocklist facts':
        ensure  => present,
        setting => 'facts.blocklist',
        value   => ['blocked-facts'],
        type    => 'array',
      }
    } else {
      hocon_setting { 'blocklist facts group':
        ensure  => absent,
        setting => 'fact-groups.blocked-facts',
      }
      hocon_setting { 'blocklist facts':
        ensure  => absent,
        setting => 'facts.blocklist',
      }
    }

    if $cachelist {
      hocon_setting { 'cachelist facts group':
        ensure  => present,
        setting => 'fact-groups.cached-facts',
        value   => $cachelist,
        type    => 'array',
      }
      -> hocon_setting { 'cachelist facts':
        ensure  => present,
        setting => 'facts.ttls',
        value   => [{'cached-facts' => $cache_ttl }],
        type    => 'array',
      }
    } else {
      hocon_setting { 'cachelist facts group':
        ensure  => absent,
        setting => 'fact-groups.cached-facts',
      }
      hocon_setting { 'cachelist facts':
        ensure  => absent,
        setting => 'facts.ttls',
      }
    }
  }
}

puppet_bootstrap::facter::blocklist:
  - kmods
  - mountpoints
  - udev
puppet_bootstrap::facter::cachelist:
  - yum_updates
  - yum_has_updates
  - yum_package_updates
  - yum_reboot_required