madwimax-git PKGBUILD to conform with AUR packaging guidelines and latest binary moves

PKGBUILD

# Maintainer: nbryskin
# Contributor: Noel Maersk <veox at wemakethings dot net>
# Contributor: Lex Rivera <x-demon@x-demon.org>

pkgname=madwimax-git
_gitname=madwimax
pkgver=20130604
pkgrel=1
pkgdesc="A reverse-engineered linux driver for Mobile Wimax (802.16e) devices based on Samsung CMC-730 chip (git version)"
arch=('i686' 'x86_64')
url="http://code.google.com/p/madwimax/"
license=('GPL2')
depends=('bash' 'libusbx')
makedepends=('asciidoc' 'docbook-xsl' 'docbook2x' 'git')
optdepends=('dhclient' 'systemd')
conflicts=('madwimax-svn' 'madwimax')
provides=('madwimax')
source=( 'git://github.com/ago/madwimax.git'
         'configure.ac.docbook2man.patch')
md5sums=('SKIP'
         'a94ec2de6ea88d204e294ac412b429ef')
backup=('etc/madwimax/config.lua')

pkgver() {
  cd $_gitname

  # recommended default
  # echo $(git rev-list --count HEAD).$(git rev-parse --short HEAD)

  # use date, for compatibility
  git log -1 --format="%cd" --date=short | sed 's/-//g'
}

prepare() {
  cd "${_gitname}"

  patch -p1 < ../../configure.ac.docbook2man.patch
}

build() {
  cd "${_gitname}"

  autoreconf --install
  ./configure --prefix=/usr --sbindir=/usr/bin --sysconfdir=/etc

  make
}

package() {
  cd "${_gitname}"

  make DESTDIR=$pkgdir install
}

# vim:syntax=sh