Clone Cleanup (PuzzleScript Script)

readme.txt

Play this game by pasting the script in http://www.puzzlescript.net/editor.html

script.txt

title Clone Cleanup
author vexorian
homepage vexorian.com
realtime_interval 0.1

========
OBJECTS
========

Background 
#404040

BorderBackground
#000000

Target 
Yellow #FFFF00
11.11
1...1
.....
1...1
11.11

Wall 
#d0d0d0 #909090
00000
01111
01111
01111
01111

Player 
Blue Black
.000.
01010
00000
01110
.000.

DeadPlayer 
#8080ff Black
.000.
01010
00100
01010
.000.


Crate 
#FFFF80 #FFFF40
.000.
01110
01110
01110
.000.


Cloner
Red Red Pink
.111.
11211
12221
11211
.111.

Uncloner
Red Black #800000 #ff3030
.222.
22222
23332
22222
.222.

BoxedCloner
Gray Red
.000.
01110
01110
01110
.000.

LeftArrow
Black #FFFF40 #FFFF80
..022
.0112
01112
.0112
..022

StaticLeftArrow
Pink

RightArrow
Black #FFFF40 #FFFF80
220..
2110.
21110
2110.
220..

StaticRightArrow
Pink

DownArrow
Black #FFFF40 #FFFF80
22222
21112
01110
.010.
..0..

StaticDownArrow
Pink

UpArrow
Black #FFFF40 #FFFF80
..0..
.010.
01110
21112
22222

StaticUpArrow
Pink



LeftConveyor
Gray Gray #353535
22112
21222
12222
21222
22112

RightConveyor
Gray Gray #353535
21122
22212
22221
22212
21122


UpConveyor
Gray Gray #353535
22122
21212
12221
12221
22222

DownConveyor
Gray Gray #353535
22222
12221
12221
21212
22122

Earth
Gray Orange
.111.
111.1
11111
1.11.
111.1

LaserCross
Gray Red
.0.0.
00.00
.....
00.00
.0.0.

UpLaser
Red
..0..
..0..
..0..
..0..
..0..

DownLaser
Red
..0..
..0..
..0..
..0..
..0..


RightLaser
Red
.....
.....
00000
.....
.....

LeftLaser
Red
.....
.....
00000
.....
.....

ConveyorSwitch
Black Blue Gray
.000.
01110
22222
22222
22222

SwitchTrigger
red

PressedSwitch
Black Blue Gray
.222.
22222
20002
02220
22222

TempConveyor
transparent

=======
LEGEND
=======

. = Background
# = Wall
P = Player
* = Crate
@ = Crate and Target
O = Target
C = Cloner
U = Uncloner
2 = DownArrow
4 = LeftArrow
6 = RightArrow
8 = UpArrow
> = RightConveyor
^ = UpConveyor
v = DownConveyor
< = LeftConveyor
e = Earth
x = LaserCross
z = BoxedCloner
/ = Crate and UpConveyor
\ = Crate and DownConveyor
" = Crate and LeftConveyor
' = Crate and RightConveyor
T = ConveyorSwitch
: = BorderBackground


Conveyor = RightConveyor or UpConveyor or DownConveyor or LeftConveyor or TempConveyor
Arrow = LeftArrow or RightArrow or DownArrow or UpArrow or StaticLeftArrow or StaticRightArrow or StaticDownArrow or StaticUpArrow
Pushable = Crate or Arrow or DeadPlayer or BoxedCloner
Clonable = Player or Pushable or Earth
Movable = Player or Pushable or Cloner or Uncloner
Laser = UpLaser or DownLaser or LeftLaser or RightLaser
LaserBarrier = Pushable or Wall or Player or Earth or Cloner or Uncloner or ConveyorSwitch or PressedSwitch
UpLaserOrigin = UpLaser or LaserCross
DownLaserOrigin = DownLaser or LaserCross
RightLaserOrigin = RightLaser or LaserCross
LeftLaserOrigin = LeftLaser or LaserCross
Yellow = Arrow or Crate


( 8
 4 6
  2  )

=======
SOUNDS
=======

SFX0 977103   (clone)
SFX1 70044902 (unclone)
SFX2 75104302 (laser kills player)
SFX3 41701308 (conveyor moves something)
SFX4 7534107 (remove earth)
SFX5 76873507 (push button)
EndLevel 30738908

================
COLLISIONLAYERS
================

Background
BorderBackground
Target , Conveyor
UpLaser
LeftLaser
DownLaser
RightLaser
Player, Wall, Crate, Cloner, Uncloner, Clonable, Earth , LaserCross, BoxedCloner, ConveyorSwitch, PressedSwitch
SwitchTrigger

======
RULES     
======

[ Player Laser ] -> [ DeadPlayer Laser ] SFX2
[ BoxedCloner Laser ] -> [ Cloner Laser ]
[ Laser LaserBarrier ] -> [ LaserBarrier ]
up [ UpLaser | Player ] -> [ UpLaser | DeadPlayer ]
down [ DownLaser | Player ] -> [ DownLaser | DeadPlayer ]
right [ RightLaser | Player ] -> [ RightLaser | DeadPlayer ]
left [ LeftLaser | Player ] -> [ LeftLaser | DeadPlayer ]

up [ UpLaser | BoxedCloner ] -> [ UpLaser | Cloner ]
down [ DownLaser | BoxedCloner ] -> [ DownLaser | Cloner ]
right [ RightLaser | BoxedCloner ] -> [ RightLaser | Cloner ]
left [ LeftLaser | BoxedCloner ] -> [ LeftLaser | Cloner ]



[ Clonable | Cloner ] -> [ Clonable | > Clonable ] SFX0
[ Clonable | Uncloner ] -> [ > Cloner |  ] SFX1

[ RightArrow ] -> [ Right StaticRightArrow ]
[ LeftArrow ] -> [ Left StaticLeftArrow ]
[ UpArrow ] -> [ Up StaticUpArrow ]
[ DownArrow ] -> [ Down StaticDownArrow ]
late [ StaticRightArrow ] -> [ RightArrow ]
late [ StaticDownArrow ] -> [ DownArrow ]
late [ StaticUpArrow ] -> [ UpArrow ]
late [ StaticLeftArrow ] -> [ LeftArrow ]

[ Movable UpConveyor ] -> [ up Movable UpConveyor ] SFX3
[ Movable RightConveyor ] -> [ right Movable RightConveyor ] SFX3
[ Movable LeftConveyor ] -> [ left Movable LeftConveyor ] SFX3
[ Movable DownConveyor ] -> [ down Movable DownConveyor ] SFX3
[ > Player | Earth  ] -> [  | Player ] SFX4


late [ LaserCross ] -> [ LaserCross UpLaser LeftLaser RightLaser DownLaser ]

late up [ UpLaser | No LaserBarrier ] -> [ UpLaser | UpLaser ]
down [ UpLaser No LaserCross | No UpLaserOrigin ] -> [ | No UpLaserOrigin ]

late right [ RightLaser | No LaserBarrier ] -> [ RightLaser | RightLaser ]
left [ RightLaser No LaserCross | No RightLaserOrigin ] -> [ | No RightLaserOrigin ]

late left [ LeftLaser | No LaserBarrier ] -> [ LeftLaser | LeftLaser ]
right [ LeftLaser No LaserCross | No LeftLaserOrigin ] -> [ | No LeftLaserOrigin ]

late down [ DownLaser | No LaserBarrier ] -> [ DownLaser | DownLaser ]
up [ DownLaser No LaserCross | No DownLaserOrigin ] -> [ | No DownLaserOrigin ]

down [ down Player | ConveyorSwitch ] -> [ Player | ConveyorSwitch SwitchTrigger ] SFX5

[ PressedSwitch ] -> [ ConveyorSwitch ]
late [ LeftConveyor ][ SwitchTrigger ] -> [ TempConveyor ][ SwitchTrigger ]
late [ RightConveyor ][ SwitchTrigger ] -> [ LeftConveyor ][ SwitchTrigger ]
late [ TempConveyor ][ SwitchTrigger ] -> [ RightConveyor ][ SwitchTrigger ]

late [ UpConveyor ][ SwitchTrigger ] -> [ TempConveyor ][ SwitchTrigger ]
late [ DownConveyor ][ SwitchTrigger ] -> [ UpConveyor ][ SwitchTrigger ]
late [ TempConveyor ][ SwitchTrigger ] -> [ DownConveyor ][ SwitchTrigger ]

late [ SwitchTrigger  ConveyorSwitch ] -> [ PressedSwitch  ]
late [ SwitchTrigger ] -> [   ]


[ >  Player | Pushable ] -> [  >  Player | > Pushable  ]









(For debug 
[ action Player ] -> win )

==============
WINCONDITIONS
==============

All Target on Yellow

=======     
LEVELS
=======

Message - Finally! We've been looking all over the world for people willing to work for us cleaning up our labs.


Message Why are you so blue? It's your first day at an exciting new job. You'll be surrounded by science! And the job couldn't be easier.

Message Just put all those yellow containers on the assigned container locations.

Message Use arrow keys to move and press r to undo.

Message If you see a red blob thing, definitely do not touch it. Dr. Hertz has been working on that experiment and doesn't want it to be disturbed.


#######
#c....#
#...o.#
#.P...#
#.*.*.#
#....o#
#######

Message - See? It wasn't hard at all. I hope you didn't touch the red goo.

Message This lab is supposed to have two yellow containers. Guess you'll have to go all the way to the 45-th floor to find a replacement container.

Message Elevators are for Authorized personel only and have been disabled during cleaning hours.

#########
#.......#
#....c..#
#..##.###
#...@.o.#
#..P....#
#########

Message - There's some dirt blocking this container, you are going to have to clean up the dirt before moving it.

#################
#......##.#.....#
#.....e##^#...c.#
#.....e##^#.....#
#....oe*.^......#
#....###...eep..#
#....###....ee..#
#.....<.........#
#################


Message - Due to the lack of willing crew members we've contracted the services of a company that makes self-moving containers.

Message For 10 dollars a month the container moves in one direction exclusively. For 10000000 dollars a month, the container moves in more than one direction.

Message So.. I wouldn't be worrying much about my job security if I were you.

############
##o.######o#
##ee...###.#
##Pe#u..##.#
#........*o#
#....#####.#
##e....o##.#
##8...*.##.#
##.#....##8#
############

Message Dr Hert'z Log #98
Message Progress in my analysis of sample #420 is on schedule.
Message Too many clones at once can be burdensome. I've requested laser equipment from IT to deal with this.

######x##########
#......#..u..>*o#
#......#.....####
#.c#c#...*.p.>.o#
#............####
#########u#######
#################

Message - Hey there. Huh did those egg heads leave their computer on? Ffs it distracts the workers. I'll tell IT to shut them down.

Message Focus on your job. For example this one lab has way more containers than assigned locations... I bet you can finish this one pretty quick!

#################
#...e.......#####
#...e.....*.#xxx#
#...e.p...*....o#
#..6e.....*....o#
#.........*....o#
#..uuuuu..*....o#
#...........#xxx#
#################

Message Dr Hertz log #801
Message The Clones are no longer a problem. The corpses have begun to use too much room though.

#############
#...#x#...ee#
#...>v#...u.#
#.c.#v#.....#
#...#>>>....#
#...#>>>..o.#
#..>>^#...@.#
#..####....p#
#...<<<.....#
#############

Message Dr Hertz log #787
Message Transporting fragments of sample #420 has been an understandably-tough logistics problem.
Message The cryptotransmutation process reacts too easily. The only exception are gray materials. So I just had an idea! A gray box that can hold #420 reasonably-safe while being transported.

Message I just need to think of a way to open the box without getting exposed to cryptotransmutation.

#################
#.............x.#
#.....P.........#
#..o.....z......#
#####...........#
##2e.....z......#
##ee.....#......#
#x.^.....#....*.#
#################

Message Dr Hertz log #787
Message Dr Ritz challenged my idea of a gray box to transport sample #420 "But how are you going to place #420 inside the box to begin with"?
Message The answer to that question is so obvious, that I refuse to document it.


##################
##...............#
#...''\..........#
#4../xv..........#
##../"<..........#
#o.......z.....c.#
#................#
#..o#2#.p........#
##################

Message - What on earth? I thought IT were supposed to shut down all computers?
Message Oh wait, this computer is a clone. I guess IT's shutdown command didn't account for this.
Message Hey you! Stop wikiwalking or whatever you kids call it now. And get back to work.
Message Look at this one lab. Ffs the container is right next to the container location. Just give it one push.

###################
#...........#o#...#
#...###.....#*#...#
#...#.#^^^^^#.#...#
#.....#^^^^^#.#####
#..##.#^^^^^#.#...#
#..#x^>^^^^^^.#.#.#
#..######...#...#.#
#...........#####.#
#........z.z.z.z..#
#..........p......#
###################

Message Dr Hertz log #1001
Message As Dr. Ritz still hasn't figured out how to put sample #420 in the gray boxes, they've been testing a conveyor belt-based system to move it.
Message This is quite ridiculous and over-complicated in comparison to my genius grey box idea.


#################
##..#.......#####
##<<<..z....>.*o#
##..#.....p.#####
##..#.......>.*o#
##..#...t...#####
##..#..###..>.*o#
##xx#.#####.#####
#################



Message - Hey! What is even that? A paper diary? Why would the scientists be wasting time on such ancient logging tech?

Message Stop getting distracted by their logs and pay attention to this room. It's disgusting!

Message Where does all this dirt come from anyway?


###################\##
###eee>.u.eeeee>...vx#
o*>pee>e.eeee.e#.t.###
###.ee>eeeee.u.#..x#o#
###c.e>eeeeee.e#^^##c#
o.>.ee>eeeeeeee>...u.#
###e*e>eeeee.ee#.<.#*#
###eee>eeee.u.e#u....#
######################

Message Dr Hertz log #199
Message While we work on solving the real complex questions about how to deal with Sample #420. Other divisions have answered the simple ones already.
Message Our Molecular experts have confirmed that the cryptotransmutation process creates an exact replica of all the molecules of whatever it touches.
Message Our Neurologists have confirmed that the clones feel pain.
Message Our Philosophers have confirmed that the clones are indeed sentient and have personhood.
Message And our Spiritists have confirmed that they do have a soul.


#x##x########
#'>#<"#......
#^##^##.#t...
e.......##p..
*#########...
eee#...e.c...
o#e#xeee....x
##e#eee######
##eeeee#:::::


Message \(vex didn't finish the text for this one \)

::::##x#########o
::::#>'####eeee##
######v####eeee##
#...##^#.##v#*#2#
#.........#...ee#
##t#####.##.##6e#
o.#..........#2e#
#.#.z.z.z.p..#ee#
#..............8x
#..#o#4#*#c######
############:::::