Knot Parameters and Functions

ChoicesAndKnots.ink

CONST name = "Dan"
~ temp fretCount = 0

It was {dayOfWeek()}.

I was unsure about asking him out on a date.

CHAPTER 1: ASKING HIM OUT

-> Chapter_1

=== Chapter_1 ===

{&What should I do? | What if I didn't say anything? | Should I ask him out?}

+ [Did he even like guys?]
    ~ fretCount++
    -> Chapter_1
    
* I should just do it!
    I let it go for weeks.  
    {fretCount > 2: After thinking about it multiple times, I finally asked him out.}
    {fretCount < 2: Finally, I asked him out. }

- CHAPTER 2: GETTING READY

Why hadn't I thought about what I was going to wear? 
Here I am, 30 minutes before the date and I haven't picked out my clothes!

* (Look_Good) [Pick out something good.] I took some time and picked out something good.
* (Random_Clothes) [Don't bother.] I just grabbed some clothes off the floor and ran out.
- Finally, I was ready.

CHAPTER 3: EATING DINNER

{Look_Good: "You look good, {name}!"}
{Random_Clothes: "Ready?"}

But I hadn't made dinner plans! And they we were, standing outside his apartment.

He turned to me. "What should we eat, {name}?"

-> Pizza_Choices("")

=== Pizza_Choices(previousChoice) ===

{previousChoice != "": (We've already talked about having {previousChoice}.) }

* [Pizza?] He shook his head. "I don't like pizza."
    -> Pizza_Choices("pizza")

* [Salad?] "Not a salad."
    -> Pizza_Choices("salad")

+ [Nothing?] {"We have to eat something!"|"Stop being silly, {name}!"}
    -> Pizza_Choices("nothing")

* [Sushi?] "Sushi sounds good!"
    We walked to the local sushi place.

-> END

=== function dayOfWeek() ===
 ~ return "{~Monday|Tuesday|Wednesday|Thursday|Friday|Saturday|Sunday}"