Portable Microsoft RDP 8 Client.

RDP8.bat

@echo off
rem This batch file unpacks the RDP 8 update for Windows 7. The unpacked RDP 8
rem client is sort of portable (the binaries are, settings are not) and will run
rem on Windows 7 and latter.
rem The update file is not part of this Gist and you will be prompted to get it
rem from official sources. English version of the client will be bundled.
rem
rem Windows6.1-KB2592687-x86.msu (SHA-1 4c11d26c8e1824643ce1caf60c30693d6536d0a2)

rem Prerequisites.
rem ============================================================================
if not EXIST Windows6.1-KB2592687-x86.msu (
  start http://www.microsoft.com/en-us/download/details.aspx?id=35393
  echo File "Windows6.1-KB2592687-x86.msu" not found in current directory.
  echo. & pause & exit /B 1
)

rem Unpack the files.
rem ============================================================================
mkdir KB2592687
expand Windows6.1-KB2592687-x86.msu -F:Windows6.1-KB2592687-x86.cab .\
expand Windows6.1-KB2592687-x86.cab -F:* KB2592687
del Windows6.1-KB2592687-x86.cab
cd KB2592687

rem Remove garbage.
rem ============================================================================
del *.cat /S
del *.mum /S
del *.manifest /S

rem Remove non-english language files, bundle *en-us* files and clean up.
rem ============================================================================
for /D %%d in (*ar-sa*, *bg-bg*, *cs-cz*, *da-dk*, *de-de*, *el-gr*, *es-es*, 
               *et-ee*, *fi-fi*, *fr-fr*, *he-il*, *hr-hr*, *hu-hu*, *it-it*, 
               *ja-jp*, *ko-kr*, *lt-lt*, *lv-lv*, *nb-no*, *nl-nl*, *pl-pl*, 
               *pt-br*, *pt-pt*, *ro-ro*, *ru-ru*, *sk-sk*, *sl-si*, *sr-..*, 
               *sv-se*, *th-th*, *tr-tr*, *uk-ua*, *zh-cn*, *zh-hk*, *zh-tw*) do (
  rmdir %%d /Q /S
)
for /D %%d in (*) do move /Y %%d\* .\
for /D %%d in (*) do rmdir %%d /Q /S

exit /B 0