A batch file that makes installing SIMPROCESS a lot easier on Windows 8 and a few more goodies.

curl.md

Getting curl.exe

• Download latest Windows Installer from https://github.com/bmatzelle/gow
  • However you will get bunch of other tools besides the cURL executable.
• Download curl.exe from http://ge.tt/7YzaW4b
  • Make sure you got file with SHA-1 1efa08c6fbec1abc6633035c852c726d8c21abd2

In both cases make sure curl.exe is on your PATH or in same directory as SIMPROCESS.bat.

SIMPROCESS.bat

@echo off
setlocal
rem Simplifies SIMPROCESS installation, renews trial license and fixes Win8 installation bug.
rem Requires curl executable on PATH. See https://github.com/bmatzelle/gow

rem Variables
for /F "usebackq tokens=2* delims= " %%o in (`reg query HKLM\Software\Microsoft\Windows\CurrentVersion\Uninstall\SIMPROCESS /v InstallLocation /reg:32 ^| findstr InstallLocation`) do set "SIMPROCESS_HOME=%%p"

rem Main
if exist "%SIMPROCESS_HOME%" (
	if not exist "%SIMPROCESS_HOME%\SPSYSTEM\InstallSettings.win.xml" (
		call :repair
	)
	call :renewlicense
	goto :run
) else (
	goto :install
)

rem Functions
goto :eof

:repair
(
	echo ^<?xml version="1.0"?^>
	echo ^<installSettings^>
	echo ^</installSettings^>
) > "%SIMPROCESS_HOME%\SPSYSTEM\InstallSettings.win.xml"
goto :eof

:renewlicense
curl -o "%SIMPROCESS_HOME%\SPSYSTEM\license.dat" "http://simprocess.com/downloads/SP_Lic.cfm?download=license&email=no-replay@example.com"
goto :eof

:run
start "" "%SIMPROCESS_HOME%\SIMPROCESS.exe" %*
exit /B 0

:install
start http://simprocess.com/directdownload/?d=trialwin
echo SIMPROCESS does not seems to be installed. Download SIMPROCESS from
echo http://simprocess.com/directdownload/?d=trialwin and try reinstalling
echo with admin rights.
pause 1>nul & exit /B 1

I didn't have 64 bit version of Windows 8 at my disposal, so drop me a line if it works with WoW64 or not.