Write version to pom, when version is resolved from BOM

build.gradle

apply plugin: 'com.android.library'
apply plugin: 'digital.wup.android-maven-publish'

android {
    compileSdkVersion 27
    buildToolsVersion '27.0.3'

    defaultConfig {
        minSdkVersion 21
        targetSdkVersion 27
        versionCode 1
        versionName "1.0"
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }

}

dependencies {
    // import a BOM
    implementation 'org.springframework.boot:spring-boot-dependencies:1.5.8.RELEASE'
    // define dependencies without versions
    implementation "com.google.code.gson:gson"
}

def getResolvedVersionOf(group, name) {
    return configurations.releaseRuntimeClasspath.resolvedConfiguration.firstLevelModuleDependencies.asList().find { e ->
        if (e.moduleGroup == group && e.moduleName == name) {
            return e
        }
    }?.moduleVersion
}

publishing {
    publications {
        aar(MavenPublication) {
            from components.android

            pom.withXml {
                Node pomNode = asNode()

                pomNode.dependencies.first().children().each { dependencyNode ->

                    // version node is not found in pom
                    if (!dependencyNode.get('version')) {

                        def groupId = dependencyNode.get('groupId').text()
                        def artifactId = dependencyNode.get('artifactId').text()
                        def version = getResolvedVersionOf(groupId, artifactId)

                        if (version) {
                            // Append resolved version
                            dependencyNode.appendNode('version', version)
                        }
                    }
                }
            }
        }
    }
}