bintray

bintray-v1.gradle

apply plugin: 'com.jfrog.bintray'

version = libraryVersion

task sourcesJar(type: Jar) {
    from android.sourceSets.main.java.srcDirs
    classifier = 'sources'
}

task javadoc(type: Javadoc) {
    options.addStringOption('Xdoclint:none', '-quiet')
    source = android.sourceSets.main.java.srcDirs
    classpath += project.files(android.getBootClasspath().join(File.pathSeparator))
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from javadoc.destinationDir
}
artifacts {
    archives javadocJar
    archives sourcesJar
}

bintray {
    user = project.hasProperty('bintrayUser') ? bintrayUser : ''
    key = project.hasProperty('bintrayKey') ? bintrayKey : ''

    configurations = ['archives']
    pkg {
        repo = bintrayRepo
        name = bintrayName
        userOrg = bintrayUserOrg
        desc = libraryDescription
        websiteUrl = siteUrl
        vcsUrl = gitUrl
        issueTrackerUrl = issueUrl
        licenses = allLicenses
        labels = ['android']
        publicDownloadNumbers = true
        version {
            desc = libraryDescription
            gpg {
                sign = true //Determines whether to GPG sign the files. The default is false
                passphrase = project.hasProperty('bintrayGpgPassword') ? bintrayGpgPassword : ''
                //Optional. The passphrase for GPG signing'
            }
        }
    }
}

install-v1.gradle

apply plugin: 'com.github.dcendents.android-maven'

group = publishedGroupId                               // Maven Group ID for the artifact

install {
    repositories.mavenInstaller {
        // This generates POM.xml with proper parameters
        pom {
            project {
                packaging 'aar'
                groupId publishedGroupId
                artifactId artifact

                // Add your description here
                name libraryName
                description libraryDescription
                url siteUrl

                // Set your license
                licenses {
                    license {
                        name licenseName
                        url licenseUrl
                    }
                }
                developers {
                    developer {
                        id developerId
                        name developerName
                        email developerEmail
                    }
                }
                scm {
                    connection gitUrl
                    developerConnection gitUrl
                    url siteUrl

                }
            }
        }
    }
}

sample-library.gradle

apply plugin: 'com.android.library'
apply plugin: 'kotlin-android'


android {
  compileSdkVersion COMPILE_SDK_VERSION as int

  defaultConfig {
    minSdkVersion MIN_SDK_VERSION as int
    targetSdkVersion TARGET_SDK_VERSION as int
  }
}

dependencies {
  implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk7:$kotlin_version"
  implementation "androidx.recyclerview:recyclerview:1.1.0"
}

ext {
  bintrayRepo = 'maven'
  bintrayName = 'recyclerview-animators'
  bintrayUserOrg = 'wasabeef'
  publishedGroupId = 'jp.wasabeef'
  libraryName = 'recyclerview-animators'
  artifact = 'recyclerview-animators'
  libraryDescription = 'Which provides simple Item animations to RecyclerView items'
  siteUrl = 'https://github.com/wasabeef/recyclerview-animators'
  gitUrl = 'https://github.com/wasabeef/recyclerview-animators.git'
  issueUrl = 'https://github.com/wasabeef/recyclerview-animators/issues'
  libraryVersion = VERSION_NAME
  developerId = 'wasabeef'
  developerName = 'Wasabeef'
  developerEmail = 'dadadada.chop@gmail.com'
  licenseName = 'The Apache Software License, Version 2.0'
  licenseUrl = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
  allLicenses = ["Apache-2.0"]
}

apply from: 'https://gist.githubusercontent.com/wasabeef/cf14805bee509baf7461974582f17d26/raw/bintray-v1.gradle'
apply from: 'https://gist.githubusercontent.com/wasabeef/cf14805bee509baf7461974582f17d26/raw/install-v1.gradle'