Testing out creating classes with slots at runtime

dynamic-class.dylan

Module: dynamic-class
Synopsis: Testing out creating classes with slots at runtime
Author: Bruce Mitchener
Copyright:

define function main (name :: <string>, arguments :: <vector>)
  let foo-gf = make(<generic-function>, required: 1, debug-name: "foo");
  let bar-gf = make(<generic-function>, required: 1, debug-name: "bar");
  let slots = vector(vector(allocation: #"instance",
                            getter: foo-gf,
                            required-init-keyword: #"foo"),
                     vector(allocation: #"instance",
                            getter: bar-gf,
                            init-value: 456,
                            init-keyword: #"bar"));
  let <dynamic-class> = make(<class>,
                             debug-name: "<dynamic-class>",
                             superclasses: vector(<object>),
                             slots: slots);
  let inst = make(<dynamic-class>, foo: 123);
  format-out("%= (%=)\n", inst, debug-name(<dynamic-class>));
  for (sd in slot-descriptors(<dynamic-class>))
    format-out("  %= = %=\n", debug-name(sd.slot-getter), slot-value(inst, sd));
  end;
  format-out("---\n");
  exit-application(0);
end function main;

main(application-name(), application-arguments());

output.txt

{<dynamic-class> #x004F01F0} ("<dynamic-class>")
  "foo" = 123
  "bar" = 456
---