PKGBUILD of valadoc-git

703688.patch

diff --git a/src/driver/0.20.x/Makefile.am b/src/driver/0.20.x/Makefile.am
index a1e7416..65cb006 100644
--- a/src/driver/0.20.x/Makefile.am
+++ b/src/driver/0.20.x/Makefile.am
@@ -8,6 +8,7 @@ AM_CFLAGS =  -g \
 	-DPACKAGE_ICONDIR=\"$(datadir)/valadoc/icons/\" \
 	-I ../../libvaladoc/ \
 	$(GLIB_CFLAGS) \
+	$(LIBGVC_CFLAGS) \
 	$(LIBGEE_CFLAGS) \
 	$(LIBVALA_0_20_X_CFLAGS) \
 	$(NULL)
diff --git a/src/driver/0.22.x/Makefile.am b/src/driver/0.22.x/Makefile.am
index 81fa37d..7659034 100644
--- a/src/driver/0.22.x/Makefile.am
+++ b/src/driver/0.22.x/Makefile.am
@@ -8,6 +8,7 @@ AM_CFLAGS =  -g \
 	-DPACKAGE_ICONDIR=\"$(datadir)/valadoc/icons/\" \
 	-I ../../libvaladoc/ \
 	$(GLIB_CFLAGS) \
+	$(LIBGVC_CFLAGS) \
 	$(LIBGEE_CFLAGS) \
 	$(LIBVALA_0_22_X_CFLAGS) \
 	$(NULL)

PKGBUILD

# Maintainer: Techlive Zheng <techlivezheng at gmail dot com>
# Contributor: SpepS <dreamspepser at yahoo dot it>

_pkgname=valadoc
pkgname=valadoc-git
pkgdesc="A documentation generator for generating API documentation from Vala source code based on libvala."
pkgver=r548.40e796b
pkgrel=1
arch=('i686' 'x86_64')
url="http://live.gnome.org/Valadoc"
source=("git://git.gnome.org/valadoc" "703688.patch")
license=('GPL')
options=('!libtool')
depends=('vala' 'libgee' 'graphviz')
makedepends=('git')
provides=("valadoc")
conflicts=("valadoc")
md5sums=('SKIP'
         '4cd250c0e42ceb6a6d87896ef21277b8')

pkgver() {
  cd "${_pkgname}"

  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
  cd "${_pkgname}"

  patch -p1 < ../703688.patch

  ./autogen.sh

  ./configure --prefix=/usr --enable-static=no

  make
}

package() {
  cd "${_pkgname}"

  make DESTDIR="${pkgdir}" install
}