MAPPER Get sessionid utility

gistfile1.txt

.@       CSID	CSID            Desc	Find Session ID in State Mgmt
*
*
*===============================================================================
@     rer,ecab$,i,2 0001 rar,ecab$,i,2 0001 .    sets-run-error-&-run-abort-rout
@     chg input$ <sessionid>s20 .
@     IF <SESSIONID> EQ ''  LDV <RSR>H1='Y'  RSR 0120 . ; . ¬BLANK INPUT?
@0110:BRK .                                                |¬CLEAR OUTPUT AREA
FKEY,0,RESUME,KEY
FKEY,1,RESUME,KEY
FKEY,2,SELECT,KEY
FKEY,4,INPUT,KEY
FKEY,10,EXIT,KEY
@     BRK  FKY,-0 .                                        |¬SET NEW FKEYS
@     LDV <MSG>S80='SELECT REPORT TO DISPLAY OR PRESS F1 TO REFRESH' .
@     srh,4000,b,1 'dhr1-4999' 'session-id' ¬,<sessionid> .
@     RNM -0 .
@     DSP,-0,,,,,,' '<MSG> .
@     IF FKEY$ EQ 10  REL . ; .                            |¬
@     IF FKEY$ EQ 4  GTO 0120 . ; .                        |¬ GET NEW INPUT
@     IF FKEY$ EQ 0,2 . ; GTO 0110 .                       |¬
@     LDV <CURV>I2=CURV$,<CURH>I2=CURH$ .                  |¬GET CURSOR POSITION
@     CHG <LN>I6 DLINE$ +<CURV> -HLINES$ -1 .              |¬
@     LZR,-0 <LNB>I7,,<LNH>I7 .                            |¬VALID LINE RANGE
@     IF <LN> GT <LNH> & LE <LNB> . ; GTO 0110 .           |¬ WITHIN RANGE?
@     RDL,-0,<LN>,0001 121-4,126-1,128-4 <CAB>I,<DRW>H,<RID>I .
@     LZR,<CAB>,<DRW>,<RID>,0110 .                         |¬DOES RID EXIST?
@ ... IF <CURH> GE 01 & LE 06 . ; GTO 0112 .               |¬ WITHIN COLUMN?
@     BRK .                                                |¬CLEAR OUTPUT AREA
FKEY,1,RESUME,KEY
FKEY,10,EXIT,KEY
@     BRK  FKY,-0 .                                        |¬SET NEW FKEYS
@     LDV <MSG>S120='PRESS RESUME (F1) TO RETURN TO LIST'\ |¬
'   -  RID ON DISPLAY IS '<RID>(P)<DRW>(P)<CAB>(P)\        |¬
'   -  SESSION ID IS '<sessionid> .                        |¬
@     DSP,<CAB>,<DRW>,<RID>,,,,,,' '<MSG>(P) .             |¬
@     IF FKEY$ EQ 10  REL . ; .                            |¬
@     GTO 0110 .                                           |¬
@0120:BRK .                                                |¬GET SCREEN
tic,";prep,(pr,bac)
FKEY,4,'CLEAR',KEY
FKEY,8,"Help  ",DSPHELP,1
FKEY,10,"Exit  ",RELEASE
fld,05,06,,70,C,(PR,li,WHI/BLA),,"FIND SESSION ID IN 1-4999B4000"
fld,08,08,01,80,,,,"SESSION ID"
fld,08,21,,20,U,(AI,ts,li,WHI/BLA),,"<SESSIONID>"
FLD,09,76,,01,,(CO,TS,li,BLA/BLA)
END
HELP 07                                    |
HELP,1
 ENTER SESSION ID NUMBER (FIND IN G-RID)
HELP,999
@     BRK  SC,-0,,,1 ' ' .                                 |¬OUT SCREEN
@     IF FKEY$ EQ 4  LDV <SESSIONID>S20  GTO 0120 . ; .    |¬RESTART
@     SC,,,,,,-1 x '' .                                    |¬FORCE TRANSMIT.
@     CHG INPUT$ <SESSIONID>S20 .                          |¬GET INFO.
@     IF <SESSIONID> EQ 0,''  GTO 0120 . ; .               |¬IS IT BLANK?
@     IF <RSR> EQ 'Y'  LDV <RSR>='N'  ESR . ; .            |¬EXIT RSR
@     GTO 0110 .                                           |¬RETURN TO TOP