Pathom cache extension example

pathom-persistent-cache.clj

(defn cache-resolver [resolver]
  (update resolver ::pc/resolve
    (fn [resolve]
      (fn [{::keys [persistent-cache*] :as env} input]
        (let [cache-key [(::pc/sym resolver) input (p/params env)]]
          (if-let [[_ v] (find @persistent-cache* cache-key)]
            v
            (let [response (resolve env input)]
              (swap! persistent-cache* assoc cache-key response)
              response)))))))

(pc/defresolver cached-resolver [env {:keys []}]
  {::pc/output    [:some-value]
   ::pc/transform cache-resolver}
  {:some-value (gensym "random")})

(def registry
  [cached-resolver])

(def parser
  (p/parser
    {::p/env     {::p/reader               [p/map-reader
                                            pc/reader2
                                            pc/open-ident-reader
                                            p/env-placeholder-reader]
                  ::p/placeholder-prefixes #{">"}}
     ::p/mutate  pc/mutate
     ::p/plugins [(pc/connect-plugin {::pc/register registry})
                  p/error-handler-plugin
                  p/trace-plugin]}))

(defonce global-atom-persistent-cache* (atom {}))

(comment
  ; re-create cache, will always get a fresh value
  (parser {::persistent-cache* (atom {})}
    [:some-value])

  ; with the persistent cache, the value will remain constant
  (parser {::persistent-cache* global-atom-persistent-cache*}
    [:some-value]))