Detect beats in Clojure

audio.clj

(ns little-lambda.server.audio
  (:require [clojure.java.io :as io])
  (:import (be.tarsos.transcoder Transcoder DefaultAttributes)
           (be.tarsos.dsp.onsets ComplexOnsetDetector OnsetHandler)
           (be.tarsos.dsp.beatroot BeatRootOnsetEventHandler)
           (be.tarsos.dsp.io.jvm AudioDispatcherFactory)))

(defn mp3->wav [source target]
  (Transcoder/transcode
    (io/file source)
    (io/file target)
    DefaultAttributes/WAV_PCM_S16LE_STEREO_44KHZ))

(defn detect-beats [source]
  (let [dispatcher (AudioDispatcherFactory/fromFile (io/file source) 512 256)
        detector (ComplexOnsetDetector. 512)
        handler (BeatRootOnsetEventHandler.)
        beats (atom [])]
    (.setHandler detector handler)
    (.addAudioProcessor dispatcher detector)
    (.run dispatcher)
    (.trackBeats
      handler
      (reify OnsetHandler
        (handleOnset [this time salience]
          (swap! beats conj time))))
    @beats))

(comment

  (mp3->wav "resources/contact.mp3" "resources/contact.wav")

  (detect-beats "resources/contact.wav")

  )