irssi-colloquy_push PKGBUILD

PKGBUILD

pkgbasename=irssi
pkgext=colloquy_push
pkgname=${pkgbasename}-${pkgext}
pkgver=0.8.16
pkgrel=1
pkgdesc="Modular text mode IRC client with Perl scripting"
arch=('i686' 'x86_64' 'armv6h')
url="http://irssi.org/"
license=('GPL')
depends=('glib2' 'openssl')
conflicts=('irssi')
provides=('irssi')
optdepends=('perl-libwww: for the scriptassist script')
backup=('etc/irssi.conf')
source=("http://irssi.org/files/${pkgbasename}-${pkgver}.tar.bz2"
        ${pkgext}.patch
        "http://static.ssji.net/${pkgext}.pl.txt")
md5sums=('4346119c4c000d0198cda17666ff1f06'
         'a0620c630c63d8285afbd414d48cbc7f'
         '9c0ed5755abdd60c1e15e710671fdbec')

build() {
  cd "${srcdir}/${pkgbasename}-${pkgver}"

  patch -p0 < "${srcdir}/${pkgext}.patch"

  ./configure --prefix=/usr \
              --enable-ipv6 \
	      --with-proxy \
	      --sysconfdir=/etc \
	      --with-perl-lib=vendor
  make
}

package() {
  cd "${srcdir}/${pkgbasename}-${pkgver}"

  make DESTDIR="${pkgdir}" install 

  install -Dm644 "$srcdir/${pkgext}.pl.txt" "$pkgdir/usr/share/irssi/scripts/${pkgext}.pl"
}