plot.gp

set terminal epslatex color
set output "plot.tex"
set key right nobox
set key spacing 1.3
set samples 200

set xlabel "$\\emph{n}$ in min$^{-1}$" offset 0,-1
set ylabel "$\\emph{F}$ in $\\emph{kN}$"
set xrange [ 0:12000]
set yrange [ 0:25]
set style arrow 1 nohead lt 0
set style line 1 lt 1 lc 1
set style line 2 lt 1 lc 2
set style line 3 lt 1 lc 3

# Fmin
set arrow from 0,6.51 to 12000,6.51 as 1
set label "$\\emph{F}_{min}$ = 6.51" at 0,6.51 offset -1,0 right

# Fmax
set arrow from 0,23.25 to 12000,23.25 as 1
set label "$\\emph{F}_{max}$ = 23.25" at 0,23.25 offset -1,0 right

# nB
set arrow from 6700,-1.5 to 6700,25 as 1
set label "$\\emph{n}_{B}$ = 6700" at 6700,0 offset 0,-2 center

# nG
set arrow from 11000,-1.5 to 11000,25 as 1
set label "$\\emph{n}_{G}$ = 11000" at 11000,0 offset 0,-2 center

C=93
N=10**6
f(x,t)=C*((10**6)/(t*60*x))**(1./3.)

plot f(x,18460) title "t$_{L1}$=18460$\\emph{h}$" ls 1,f(x,9230) title "t$_{L2}$=9230$\\emph{h}$" ls 2, f(x,36920) title "t$_{L3}$=36920$\\emph{h}$" ls 3

test.tex

\documentclass{article}
\usepackage{graphics}
\usepackage{nopageno}
\usepackage{txfonts}
\usepackage[usenames]{color}

\begin{document}
\begin{center}
\input{plot.tex}
\end{center}
\end{document}