Dumps audio file bitrate

bitclean.bat

@echo off
for /f "tokens=1-2 delims=|" %%i in ('cscript //nologo bitrate.vbs /f:"%~1" /m:"%~2"') do (
  if %%j LSS 320 echo  %%i has bitrate %%j and will be deleted
)

bitrate.vbs

sFolder = WScript.Arguments.Named("f")
sMask = WScript.Arguments.Named("m")

If LenB(sFolder) = 0 Then
    WScript.echo "usage: " & WScript.ScriptName & " /f:folder [/m:mask]"
    WScript.Quit 1
End If
If LenB(sMask) = 0 Then
    sMask = "mp3"
End If
Set oFileMatch = New RegExp
oFileMatch.IgnoreCase = True
If Left(sMask, 1) = "/" Then
    oFileMatch.Pattern = Mid(sMask, 2)
Else
    oFileMatch.Pattern = "\." & Replace(sMask, ".", vbNullString) & "$"
End If

Set oBitRateStrip = New RegExp
oBitRateStrip.Global = True
oBitRateStrip.Pattern = "[^\d]"

GetBitrate CreateObject("Shell.Application").Namespace(sFolder)

Function GetBitrate(oFolder)
    For Each oFile In oFolder.Items
        If oFile.IsFolder Then
            GetBitrate oFile.GetFolder
        ElseIf oFileMatch.Test(oFile.Name) Then
            sBitRate = oBitRateStrip.Replace(oFolder.GetDetailsOf(oFile, 28), vbNullString)
            If LenB(sBitRate) <> 0 Then
                WScript.echo oFile.Path & "|" & sBitRate
            End If
        End If
    Next    
End Function