markuplint-error-for-compilation-mode.awk

#! /usr/bin/awk -f                                                                                               

BEGIN {
  filename = ""
}

/<markuplint> ([^:])+: (.)/ { # filename                                                                         
  sub(/\:$/, "", $2)
  if ($3 == "✓") {
    filename = ""
  } else {
    filename = remove_dir($2)
  }
}

/^ +[0-9]+:[0-9]+/ {
  if (filename) {
    line = sprintf("%s:%s: ", filename, $1)
    $1 = ""
    line = line sprintf("%s ", $0)
    print line
  }
}

#                                                                                         
# @param {string} filename                                                                
# @return {string}                                                                        
#                                                                                         
function remove_dir(filename) {
  sub(ENVIRON["PWD"] "/", "", filename)
  return filename
}

markuplint の出力が

<markuplint> filename: ✗
  3:81  ✖  不正な文字は文字参照でエスケープするべきです character-reference 
  3:113 ✖  不正な文字は文字参照でエスケープするべきです character-reference 
  3:131 ✖  不正な文字は文字参照でエスケープするべきです character-reference 

みたいな感じで扱いにくい。上のスクリプトを

yarn -s markuplint --no-color -f simple <source> 2>&1 | ./markuplint-error-for-compilation-mode.awk

こんな感じで使うと

filename:line:col: error message
filename:line:col: error message
filename:line:col: error message
filename:line:col: error message
...

という形になってだいぶ扱いやすくなる。