PKGBUILD for gjs

PKGBUILD

# $Id$
# Contributor: Ionut Biru <ibiru@archlinux.org>

pkgname=gjs
pkgver=1.50.4
pkgrel=2
epoch=1
pkgdesc="Javascript Bindings for GNOME"
url="https://wiki.gnome.org/Projects/Gjs"
arch=(x86_64)
license=(GPL)
depends=(cairo gobject-introspection-runtime js52 gtk3)
makedepends=(gobject-introspection git autoconf-archive xorg-server-xvfb)
checkdepends=(valgrind)
_commit=08046ea1e25ddc682fb529496898a1153ca2fb35  # tags/1.50.4^0
source=("git+https://gitlab.gnome.org/GNOME/gjs.git#commit=$_commit"
	 'disable-destoyed-object-criticals.patch::https://src.fedoraproject.org/rpms/gjs/raw/1663b7503563515abcf55a1ed0db45b52ac2108f/f/disable-destoyed-object-criticals.patch')
sha256sums=('SKIP'
	    'c65a1ef3b290c80c78b27a77dda8e08382989a7ca145abc85bbaf3082d46d167')

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/-/+/g'
}

prepare() {
  cd $pkgname
  patch -p1 -i "${srcdir}/disable-destoyed-object-criticals.patch"
  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd $pkgname
  ./configure --prefix=/usr --disable-static --libexecdir=/usr/lib --with-xvfb-tests
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

#check() {
#  cd $pkgname
#  make -j1 check
#}

package() {
  cd $pkgname
  make DESTDIR="$pkgdir" install
}