save_session_cookie.vim

""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
"
" Auto-save the session cookie to .env for rest.nvim
"
""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""

" Set the name of the variable in the .env file which stores the HTTP request
" header for cookie:
" e.g. header_cookie_debug_session=XDEBUG_SESSION=1;app_session=I6VFFDmpeZ2uqMQhRqxaBAoRv6LypXS6phkFYbxg
let g:env_var_http_request_header_cookie = 'header_cookie_debug_session'

" Set the key contained in the Set-Cookie HTTP response header which holds the
" session cookie
let g:http_response_cookie_session = 'app_session'

autocmd BufEnter * if &filetype == 'httpResult' | call <SID>save_cookie() | endif

function s:save_cookie() abort
    let l:cookie = matchstr(getline(search('Set-Cookie:')), '\(' . g:http_response_cookie_session . '=\)\@<=\(.\{-}\)\(;\)\@=')

    if l:cookie == ''
        echoerr 'Cannot find a valid cookie.'
        return
    endif

    let l:bak_file_ext_part = ''
    if IsPlatform('mac')
        let l:bak_file_ext_part = '""'
    endif

    call system('sed -i ' . l:bak_file_ext_part . ' "s/\(' . g:env_var_http_request_header_cookie . '=.*' . g:http_response_cookie_session . '=\)[0-9A-Za-z]*/\1' . l:cookie . '/" .env')
endfunction

function! IsPlatform(mixed)"{{{
    if type(a:mixed) == 1
        let plist = [a:mixed]
    elseif type(a:mixed) == 3
        let plist = a:mixed
    else
        return 0
    endif

    if has('win16') || has('win32') || has('win64') || has('winnt')
        return index(plist, 'win')>=0
    elseif has('mac')
        return index(plist, 'mac')>=0
    else
        return index(plist, 'unix')>=0
    endif

    return 0
endfunction"}}}