Electric datalevin pending weird behaviour

core.cljc

(ns wip.datalevin
  (:require [hyperfiddle.electric :as e]
            [hyperfiddle.electric-dom2 :as dom]
            [hyperfiddle.electric-ui4 :as ui]
            #?(:clj [datalevin.core :as d]))
  (:import (hyperfiddle.electric Pending)))

#?(:clj
   (defonce !conn (d/get-conn "/tmp/foo")))

(comment
  (d/close !conn)
  (clojure.java.shell/sh "/usr/bin/rm -rf /tmp/foo")
  (alter-var-root #'!conn (constantly (d/get-conn "/tmp/foo")))
  nil)

(e/def db)

#?(:clj
   (defn add-item []
     (d/transact! !conn [{:db/id -1 :item/id (random-uuid)}])))

#?(:clj
   (defn list-items [db]
     (d/q '[:find [(pull ?e [:item/id]) ...]
            :where [?e :item/id]]
       db)))

(e/defn App []
  (e/server
    (binding [db (e/watch !conn)]
      (e/client
        (ui/button
          (e/fn [] (e/server (e/offload #(add-item)) nil))
          (dom/text "+ Add an item"))
        (dom/ul
          (try
            (e/server
              (e/for-by :item/id [{:keys [item/id]} (e/offload #(list-items db))]
                (e/client (dom/li (dom/text id)))))
            (catch Pending _ (dom/props {:style {:background-color "yellow"}}))))))))