PKGBUILD for openscad-git with experimental features

enable-experimental-features.patch

diff -ura openscad.orig/openscad.pro openscad.new/openscad.pro
--- openscad.orig/openscad.pro	2018-04-12 16:34:21.000186865 +0200
+++ openscad.new/openscad.pro	2018-04-12 16:34:05.172226469 +0200
@@ -1,3 +1,4 @@
+CONFIG += experimental
 # Environment variables which can be set to specify library locations:
 # MPIRDIR
 # MPFRDIR

PKGBUILD

# Maintainer: Kyle Keen <keenerd@gmail.com>
# Contributor: Torsten Wagner <tottiwagner@yahoo.de>

pkgname=openscad-git
pkgver=20180527
pkgrel=1
pkgdesc="The programmers solid 3D CAD modeller"
arch=('i686' 'x86_64')
license=('GPL2')
url="http://openscad.org/"
provides=('openscad')
conflicts=('openscad')
depends=('qt5-base' 'qt5-multimedia' 'qscintilla-qt5' 'cgal' 'opencsg' 'boost-libs')
makedepends=('git' 'boost' 'eigen' 'imagemagick' 'ccache')
source=('git+https://github.com/openscad/openscad.git'
        'git+https://github.com/openscad/MCAD.git'
        'enable-experimental-features.patch')

md5sums=('SKIP'
         'SKIP'
         '3da8e8cb69418acb22e4e405022fd709')

_gitname="openscad"
_gitbranch="master"

pkgver() {
  cd "$_gitname"
  git show -s --format="%ci" HEAD | sed -e 's/-//g' -e 's/ .*//'
}

prepare() {
  cd "$_gitname"
  # enable experimental features
  patch -Np1 -i "$srcdir/enable-experimental-features.patch"
}

build() {
  cd "$_gitname"
  # submodules seem kind of weird with the detached bare repo
  cp -ar "$srcdir/MCAD" libraries
  rm -f libraries/MCAD/*.py
  rm -rf libraries/MCAD/.git/
  qmake-qt5 PREFIX="/usr" VERSION="$pkgver"
  make
  convert "icons/openscad.png" -resize 128x128\> "icons/openscad-128.png"
}

package() {
  cd "$_gitname"
  make INSTALL_ROOT="$pkgdir"  install
  install -Dm644 "icons/openscad.desktop" "$pkgdir/usr/share/applications/openscad.desktop"
  install -Dm644 "icons/openscad-128.png" "$pkgdir/usr/share/pixmaps/openscad.png"
}