Created
May 10, 2012 14:42
-
-
Save xpathr/2653581 to your computer and use it in GitHub Desktop.
Url-encode by Cremol
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
<?xml version="1.0" encoding="utf-8"?> | |
<xsl:stylesheet version="1.0" | |
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> | |
<!-- | |
ISO-8859-1 based URL-encoding demo | |
Written by Mike J. Brown, mike@skew.org. | |
Updated 2002-05-20. | |
No license; use freely, but credit me if reproducing in print. | |
Also see http://skew.org/xml/misc/URI-i18n/ for a discussion of | |
non-ASCII characters in URIs. | |
Usage: | |
<xsl:call-template name="decode"> | |
<xsl:with-param name="str" select="$url"/> | |
</xsl:call-template> | |
<xsl:call-template name="encode"> | |
<xsl:with-param name="str" select="$url"/> | |
</xsl:call-template> | |
--> | |
<xsl:variable name="hex" select="'0123456789ABCDEF'"/> | |
<xsl:variable name="ascii"> !"#$%&'()*+,-./0123456789:;<=>?@ABCDEFGHIJKLMNOPQRSTUVWXYZ[\]^_`abcdefghijklmnopqrstuvwxyz{|}~</xsl:variable> | |
<xsl:variable name="safe">!'()*-.0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ_abcdefghijklmnopqrstuvwxyz~</xsl:variable> | |
<xsl:variable name="latin1"> ¡¢£¤¥¦§¨©ª«¬­®¯°±²³´µ¶·¸¹º»¼½¾¿ÀÁÂÃÄÅÆÇÈÉÊËÌÍÎÏÐÑÒÓÔÕÖ×ØÙÚÛÜÝÞßàáâãäåæçèéêëìíîïðñòóôõö÷øùúûüýþÿ</xsl:variable> | |
<xsl:template name="decode"> | |
<xsl:param name="str"/> | |
<xsl:choose> | |
<xsl:when test="contains($str,'%')"> | |
<xsl:value-of select="substring-before($str,'%')"/> | |
<xsl:variable name="hexpair" select="translate(substring(substring-after($str,'%'),1,2),'abcdef','ABCDEF')"/> | |
<xsl:variable name="decimal" select="(string-length(substring-before($hex,substring($hexpair,1,1))))*16 + string-length(substring-before($hex,substring($hexpair,2,1)))"/> | |
<xsl:choose> | |
<xsl:when test="$decimal < 127 and $decimal > 31"> | |
<xsl:value-of select="substring($ascii,$decimal - 31,1)"/> | |
</xsl:when> | |
<xsl:when test="$decimal > 159"> | |
<xsl:value-of select="substring($latin1,$decimal - 159,1)"/> | |
</xsl:when> | |
<xsl:otherwise>?</xsl:otherwise> | |
</xsl:choose> | |
<xsl:call-template name="decode"> | |
<xsl:with-param name="str" select="substring(substring-after($str,'%'),3)"/> | |
</xsl:call-template> | |
</xsl:when> | |
<xsl:otherwise> | |
<xsl:value-of select="$str"/> | |
</xsl:otherwise> | |
</xsl:choose> | |
</xsl:template> | |
<xsl:template name="url-encode"> | |
<xsl:param name="str"/> | |
<xsl:if test="$str"> | |
<xsl:variable name="first-char" select="substring($str,1,1)"/> | |
<xsl:choose> | |
<xsl:when test="contains($safe,$first-char)"> | |
<xsl:value-of select="$first-char"/> | |
</xsl:when> | |
<xsl:otherwise> | |
<xsl:variable name="codepoint"> | |
<xsl:choose> | |
<xsl:when test="contains($ascii,$first-char)"> | |
<xsl:value-of select="string-length(substring-before($ascii,$first-char)) + 32"/> | |
</xsl:when> | |
<xsl:when test="contains($latin1,$first-char)"> | |
<xsl:value-of select="string-length(substring-before($latin1,$first-char)) + 160"/> | |
</xsl:when> | |
<xsl:otherwise> | |
<xsl:message terminate="no">Warning: string contains a character that is out of range! Substituting "?".</xsl:message> | |
<xsl:text>63</xsl:text> | |
</xsl:otherwise> | |
</xsl:choose> | |
</xsl:variable> | |
<xsl:variable name="hex-digit1" select="substring($hex,floor($codepoint div 16) + 1,1)"/> | |
<xsl:variable name="hex-digit2" select="substring($hex,$codepoint mod 16 + 1,1)"/> | |
<xsl:value-of select="concat('%',$hex-digit1,$hex-digit2)"/> | |
</xsl:otherwise> | |
</xsl:choose> | |
<xsl:if test="string-length($str) > 1"> | |
<xsl:call-template name="url-encode"> | |
<xsl:with-param name="str" select="substring($str,2)"/> | |
</xsl:call-template> | |
</xsl:if> | |
</xsl:if> | |
</xsl:template> | |
</xsl:stylesheet> |
Sign up for free
to join this conversation on GitHub.
Already have an account?
Sign in to comment