Breadth-first search cheap-version of GNU find in Zig

bfs_find.zig

const std = @import("std");
const allocator = std.heap.c_allocator;

const DirQueue = std.TailQueue(std.fs.IterableDir);

pub fn main() !void {
    var argv = try std.process.argsWithAllocator(allocator);
    defer argv.deinit();

    _ = argv.skip();

    const searchString: []const u8 = argv.next() orelse return;
    const searchDir = argv.next() orelse ".";

    const stdout = std.io.getStdOut().writer();

    var dirList = DirQueue{};

    dirList.append(blk: {
        var node = try allocator.create(DirQueue.Node);
        node.data = try std.fs.cwd().openIterableDir(searchDir, .{});
        break :blk node;
    });

    while (true) {
        var dirIterNode = dirList.popFirst() orelse break;
        defer allocator.destroy(dirIterNode);

        var dirIter = dirIterNode.data;
        defer dirIter.close();

        var iterator = dirIter.iterate();
        while (try iterator.next()) |entry| {
            if (entry.kind == .Directory) {
                dirList.append(blk: {
                    var node = try allocator.create(DirQueue.Node);
                    node.data = try dirIter.dir.openIterableDir(entry.name, .{});
                    break :blk node;
                });
            }

            var path: [std.fs.MAX_PATH_BYTES:0]u8 = undefined;

            if (std.mem.eql(u8, entry.name, searchString))
                try stdout.print("{s}\n", .{try dirIter.dir.realpath(entry.name, &path)});
        }
    }
}