Org Mode でリンク種別に応じたプレフィクスを表示する

org-link-prefixes-init.el

(require 'ol)
(defconst my-org-link-prefixes '(("id" . "🦄")
                                 ("roam" . "🦄")
                                 ("attachment" . "📎")
                                 ("file" . "💾")
                                 ("file+sys" . "💾")
                                 ("file+emacs" . "🗒")
                                 ("shell" . "💻")
                                 ("https" . "🌐")
                                 ("http" . "🌐")
                                 ("help" . "❓")
                                 ("info" . "ℹ")
                                 ("elisp" . "⚡")))

(defun my-org-link-on-modification (ov changed _start _end &optional _len)
  (when changed (delete-overlay ov)))

(defun my-org-link-activate (type start end bracketp)
  (remove-overlays start end 'org-link-prefix t)
  (when (and org-link-descriptive bracketp)
    (let* ((prefix (or (when-let ((found (cdr-safe (assoc-string type my-org-link-prefixes))))
                         (format "%s " found))
                       (format "%s:" (upcase type))))
           (ov (make-overlay start end))
           (props `((org-link-prefix . t)
                    (before-string . ,prefix)
                    (evaporate . t)
                    (modification-hooks . ,(list #'my-org-link-on-modification))
                    (insert-in-front-hooks . ,(list #'my-org-link-on-modification)))))
      (dolist (prop props)
        (overlay-put ov (car prop) (cdr prop))))))

(dolist (prefix my-org-link-prefixes)
  (let ((type (car prefix)))
    (org-link-set-parameters type
                             :activate-func
                             `(lambda (start end _path bracketp)
                                (my-org-link-activate ,type start end bracketp)))))