Server-sent events in Elixir with Plug

sse_demo_plug.ex

defmodule SSEDemoPlug do
  use Plug.Router

  plug Plug.Logger
  plug(:match)
  plug(:dispatch)

  get "/" do
    html = """
  <ul></ul>
  <script>
  var evtSource = new EventSource('sse');
    var eventList = document.querySelector('ul');

    evtSource.onmessage = function(e) {
      var newElement = document.createElement("li");

      newElement.textContent = "message: " + e.data;
      eventList.appendChild(newElement);
    }
  </script>
"""

    conn
    |> put_resp_content_type("text/html")
    |> send_resp(200, html)
  end

  get "/sse" do
    conn =
      conn
      |> put_resp_content_type("text/event-stream")
      |> send_chunked(:ok)

    ~w(each chunk as a word)
    |> Stream.cycle()
    |> Enum.reduce_while(conn, fn chunk, conn ->
      result =
        case Plug.Conn.chunk(conn, "data: #{chunk}\n\n") do
          {:ok, conn} ->
            {:cont, conn}

          {:error, :closed} ->
            {:halt, conn}
        end

      :timer.sleep(1000)
      result
    end)
  end

  match _ do
    send_resp(conn, 404, "Oops!")
  end
end