Linear Escape

Linear Escape.i7

"Linear Escape" by Jiayu Yi

Dead End is a dark room. "[if unvisited]You wake up in[otherwise]The room you woke up in is[end if] a small room with a single exit to the south."

A lit thing called a torch is in the Dead End.

The strangely-shaped rock is carried by the player.

South of the Dead End is the Overgrown Chamber. The Overgrown Chamber is a dark room. "You find yourself in a large chamber. The walls are covered with vegetation, and [sturdy vines] hang from the ceiling. The middle is occupied by a large, [ceremonial brazier]. [if the ceremonial brazier is lit]There are exits to the north and south.[otherwise]There is an exit to the north, but a stone door blocks the way south."

A thing called sturdy vines are in the Overgrown Chamber.

An unlit thing called the ceremonial brazier is in the Overgrown Chamber. The ceremonial brazier is fixed in place in the Overgrown Chamber.

Before printing the name of the ceremonial brazier:
	if the ceremonial brazier is lit:
		say "lit ";
	otherwise:
		say "unlit ".

The block burning rule does nothing when the noun is the ceremonial brazier.

Before burning the ceremonial brazier:
	if the player is carrying a lit torch:
		now the ceremonial brazier is lit;
		say "You use your torch to light the ceremonial brazier. As the flame roars to life, there is a sudden rumbling noise, and the stone doorway to the south slowly opens."

Before taking the sturdy vines:
	if the player is not carrying sturdy vines:
		say "You tug hard on a particularly low-hanging vine, and a decent length of it falls to the ground. This would make for a good rope."
		
Before going from the Overgrown Chamber to the Rocky Overhang:
	if the ceremonial brazier is unlit:
		say "The way south is blocked by a stone door.";
		stop the action.
		
Rope used is initially false.

Rocky Overhang is south of the Overgrown Chamber. "You are on a rocky overhang several meters above the ground, too high up to jump down safely[if rope used is true], but there is a vine rope you can use to climb down[end if]. There is an exit to the north. A path continues to the south below."

Before going from the Rocky Overhang to the Tunnel:
	if the player is carrying sturdy vines:
		say "You tie one end of the length of sturdy vine you brought along to a solid-looking stalagmite and use it to climb down safely.";
		now rope used is true;
		remove sturdy vines from play;
	otherwise if rope used is false:
		say "There's no way to go down safely!";
		stop the action.

Tunnel is south of the Rocky Overhang and down from the Rocky Overhang. "You are in a tunnel, lit by evenly-spaced flickering torches along the walls. To the north is a several meter high sheer cliff under a rocky overhang, but there is a vine rope you can use to climb up. The tunnel extends to the south with gentle upwards incline."

Vestibule is south of the Tunnel.  "You are momentarily blinded by the glare of sunlight shining through large stained glass windows decorating the southern wall of the room you entered. There is an exit to the north."

Some stained-glass windows are scenery in the Vestibule.

Instead of attacking windows, say "The windows are too high up for you to reach."

The stone door is a locked door. It is south of the Vestibule. Through it is Freedom. "To the south, underneath the stained glass windows is a stone door that appears to lead outside."

The description of the stone door is "There is a strangely-shaped slot in it."

The strangely-shaped rock unlocks the stone door.

Freedom is a room. "You have made it out of the caves! You have no idea how you ended up in there in the first place, but this is still something to celebrate! As you walk off into the distance, you think about how to get back to your usual life."

After going to Freedom:
	produce a room description with going spacing conventions;
	end the story finally.

Release along with an interpreter.