PKGBUILD

# Maintainer: Severen Redwood <severen@shrike.me
# Contributor: Dave Reisner <dreisner@archlinux.org>
# Contributor: Matthias Blaicher <matthias@blaicher.com>
# Contributor: Christopher Arndt <aur -at- chrisarndt -dot- de>
# Contributor: Luca Weiss <luca (at) z3ntu (dot) xyz>
# Report all package issues to `https://github.com/SShrike/pkgbuilds`

_pkgname=capnproto
pkgname="${_pkgname}-git"
pkgver=r1853.6e1d2317
pkgrel=1
pkgdesc="Cap'n Proto serialization/RPC system"
arch=('i686' 'x86_64')
url="http://kentonv.github.io/capnproto/"
license=('MIT')
makedepends=('git' 'subversion')
conflicts=("${_pkgname}")
provides=("${_pkgname}")
source=("${_pkgname}::git+https://github.com/kentonv/${_pkgname}.git"
        "https://github.com/google/googletest/archive/release-1.8.0.tar.gz")
md5sums=('SKIP'
         '16877098823401d1bf2ed7891d7dce36')

pkgver() {
  cd "${srcdir}/${_pkgname}"
  echo r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)
}

prepare() {
  cd "${srcdir}/${_pkgname}/c++"
  ln -sf "${srcdir}/gtest"
  mkdir -p build
}

build() {
  cd "${srcdir}/${_pkgname}/c++/build"
  cmake .. -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_BUILD_TYPE=Release -DCMAKE_INSTALL_LIBDIR=/usr/lib
  make
}

check() {
  cd "${srcdir}/${_pkgname}/c++/build"
  make check
}

package() {
  cd "${srcdir}/${_pkgname}/c++/build"
  make DESTDIR="$pkgdir" install

  install -D -m644 "../../LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

# vim:set ts=2 sw=2 et: