PKGBUILD for ropgadget-git in AUR

PKGBUILD

# Maintainer: Levente Polyak <levente[at]leventepolyak[dot]net>
# Contributor: Firas Zaidan <firas@zaidan.de>

pkgname=ropgadget-git
pkgver=5.4.415.016d0a9
pkgrel=1
pkgdesc="Search gadgets in binaries to facilitate ROP exploitation for several file formats and architectures"
url="http://www.shell-storm.org/project/ROPgadget"
arch=('any')
license=('GPL2')
depends=('python2-capstone')
makedepends=('git' 'python2-setuptools')
provides=('ropgadget')
conflicts=('ropgadget')
source=(${pkgname}::git+https://github.com/JonathanSalwan/ROPgadget)
sha512sums=('SKIP')

pkgver() {
  cd ${pkgname}
  printf "%s.%s.%s" "$(git describe --tags --abbrev=0|cut -dv -f2)" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

check() {
  cd ${pkgname}/test-suite-binaries
  ./test.sh
}

prepare() {
  cd ${pkgname}
  sed -i 's/python/python2/g' setup.py ROPgadget.py scripts/ROPgadget test-suite-binaries/test.sh 
}

package() {
  cd ${pkgname}
  python2 setup.py install -O1 --root="${pkgdir}" --prefix=/usr
}

# vim:set ts=2 sw=2 et: