Skip to content

Instantly share code, notes, and snippets.

@zancarius zancarius/PKGBUILD
Last active May 24, 2016

Embed
What would you like to do?
Sentry PKGBUILD with dsym support
pkgname=sentry-dsym
pkgver=8.4.1
pkgrel=1
pkgdesc="Python-based realtime logging and aggregation server with dsym."
arch=(any)
url="http://pypi.python.org/pypi/sentry"
license=(BSD)
conflicts=(sentry)
provides=(sentry)
depends=(
jansson
libxml2
libxslt
llvm
python2
postgresql
redis
)
makedepends=(python2-pip python2-setuptools python2-virtualenv)
options=(!strip)
install="sentry.install"
source=(
"sentry.install"
"sentry.service"
"sentry-celery.service"
)
sha256sums=(
a8e29037fe9876230e74bc9205c950222a1b8d2319a45e472616b88d637cf076 # sentry.install
5b6506920c365466d9b8e29935ebbeedbc30b388f29eca370568728d4e529976 # sentry.service
6188e3fca3e9b4a6fd32fd3a9f39a3e4b489632b79cc6db307d767066fbbe518 # sentry-celery.service
)
package () {
mkdir -p "${pkgdir}/opt/sentry"
virtualenv2 --python=python2.7 "${pkgdir}/opt/sentry"
source "${pkgdir}/opt/sentry/bin/activate"
# Begin Sentry installation for our specific version via PyPI. This
# guarantees we'll grab all of the appropriate dependencies and
# automates the process.
#
# If you're running GCC 6.1 and Sentry won't build, uncomment the following
# line and comment-out or remove the one immediately after it. If you wish
# to be more specific, replace -Wno-error with -Wno-misleading-indentation.
#CFLAGS="-Wno-error" "${pkgdir}/opt/sentry/bin/pip" install "sentry==${pkgver}"
"${pkgdir}/opt/sentry/bin/pip" install "sentry[dsym]==${pkgver}"
# Make certain the virtualenv is relocatable.
virtualenv2 --relocatable "${pkgdir}/opt/sentry"
sed -i "s#${pkgdir}##" "${pkgdir}/opt/sentry/bin/activate"
mkdir -p "${pkgdir}/opt/sentry/.python-eggs"
mkdir -p "${pkgdir}/etc/sentry"
# Remove Desktop Services Store from package. At least one of these files
# still persists in the Sentry package. They're harmless, but I don't like
# them. :) More information: http://en.wikipedia.org/wiki/.DS_Store
find "${pkgdir}" -name '.DS_Store' -delete
install -Dm0644 "${srcdir}/sentry.service" "${pkgdir}/usr/lib/systemd/system/sentry.service"
install -Dm0644 "${srcdir}/sentry-celery.service" "${pkgdir}/usr/lib/systemd/system/sentry-celery.service"
}
Sign up for free to join this conversation on GitHub. Already have an account? Sign in to comment
You can’t perform that action at this time.