Skip to content

Instantly share code, notes, and snippets.

@zeegin

zeegin/1cv8.bat

Last active Jul 23, 2021
Embed
What would you like to do?
BSL Build cf from EDT
@echo off
SETLOCAL
set LOGFILE=%temp%\%random%.log
if exist %LOGFILE% (
del /f /s /q %LOGFILE% > nul
)
"C:\Program Files\1cv8\current\bin\1cv8" %* /Out %LOGFILE%
set RESULT=%ERRORLEVEL%
echo ExitCode=%RESULT%
powershell -Command Get-Content %LOGFILE%
if exist %LOGFILE% (
del /f /s /q %LOGFILE% > nul
)
exit /b %RESULT%
@echo off
set CI_PROJECT_DIR=%~dp0/../
set PRJ=%CI_PROJECT_DIR%/EDT_PROJECT_DIR
set WP=%CI_PROJECT_DIR%/bin/w
set XML=%CI_PROJECT_DIR%/bin/xml
set IB=File="%CI_PROJECT_DIR%/bin/db"
set CF=%CI_PROJECT_DIR%/bin/1cv8.cf
call ring edt workspace export --workspace-location %WP% --project %PRJ% --configuration-files %XML%
pushd %~dp0
call 1cv8 CREATEINFOBASE %IB%
call 1cv8 DESIGNER /WA- /DisableStartupDialogs /IBConnectionString %IB% /LoadConfigFromFiles %XML% /UpdateDBCfg
call 1cv8 DESIGNER /WA- /DisableStartupDialogs /IBConnectionString %IB% /CreateDistributionFiles -cffile %CF%
popd
@echo off
if /%1 == / goto help
pushd "C:\Program Files\1cv8"
if exist current\ rmdir current
mklink /j current %1
popd
goto end
:help
echo set-current-version - Makes symbolic links pointing to current 1C-Enterprise version's folders
echo Parameter: 1C-Enterprise version number
echo Example: set-current-version 8.3.5.1248
:end
Sign up for free to join this conversation on GitHub. Already have an account? Sign in to comment