iw sacn.awk busybox

scan.awk

# iw wlan0 scan | sed -e 's#(on wlan# (on wlan#g' | awk -f scan.awk
BEGIN {
  printf("%s|%s|%s|%s|%s|%s|%s|%s|%s|%s\n","MAC","SSID","freq","signal","sig%","WPA","WPA2","WEP","TKIP","CCMP");
}

NF > 0{
  if ($1 == "BSS") {
    if( $2 ~ /^[a-z0-9:]{17}$/ ) {
      if( e["MAC"] ){
        printf("%s|%s|%s|%s|%s|%s|%s|%s|%s|%s\n",e["MAC"],e["SSID"],e["freq"],e["sig"],e["sig%"],e["WPA"],e["WPA2"],e["WEP"],e["TKIP"],e["CCMP"]);
      }
      e["MAC"] = $2;
      e["WPA"] = "n";
      e["WPA2"] = "n";
      e["WEP"] = "n";
      e["TKIP"] = "n";
      e["CCMP"] = "n";
    }
  }

  if ($1 == "SSID:") {
    e["SSID"] = substr($0, index($0,$2));
  }

  if ($1 == "freq:") {
    e["freq"] = $NF;
  }

  if ($1 == "signal:") {
    e["sig"] = $2 " " $3;
    e["sig%"] = (60 - ((-$2) - 40)) * 100 / 60;
  }

  if ($1 == "WPA:") {
    e["WPA"] = "y";
  }

  if ($1 == "RSN:") {
    e["WPA2"] = "y";
  }

  if ($1 == "WEP:") {
    e["WEP"] = "y";
  }

  if ($4 == "CCMP" || $5 == "CCMP") {
    e["CCMP"] = "y";
  }

  if ($4 == "TKIP" || $5 == "TKIP") {
    e["TKIP"] = "y";
  }
}

END {
  printf("%s|%s|%s|%s|%s|%s|%s|%s|%s|%s\n",e["MAC"],e["SSID"],e["freq"],e["sig"],e["sig%"],e["WPA"],e["WPA2"],e["WEP"],e["TKIP"],e["CCMP"]);
}