abstract service ACS

abstract.coffee

class AbstractService
    constructor: (@cloud)->

    defaultSearchCondition: (searchCondition = {})->
        searchCondition.response_json_depth or= 3
        searchCondition

    buildArrowQueryString: (methodName)=> "/v1/#{@apiName}/#{methodName}.json"

    getObjectsFromResponse: (response)=> response?.response?[@apiName] or []

    get: (methodName, searchCondition)=>
        @cloud.getAsync @buildArrowQueryString(methodName), searchCondition
        .then (response)->
            if response?.body?.meta?.code is 200
                response.body
            else
                error = new Error "Call to cloud was failed"
                error.status = 500
                throw error
        .then (response)=>
            @getObjectsFromResponse(response)
        .catch (error)->
            console.log "ERROR #{error}"
            throw error

    show: (searchCondition = @defaultSearchCondition searchCondition)=>
        #default settings
        @get "show", searchCondition



    query: (searchCondition = @defaultSearchCondition searchCondition)=>
        #default settings
        searchCondition.isArray = yes
        searchCondition.limit or= 250

        @get "query", searchCondition


module.exports = AbstractService

objects.coffee

AbstractService = require "./abstract"

class CustomObjects extends AbstractService
    constructor: (@cloud)->
        @apiName = "objects"

    buildArrowQueryString: (methodName)=> "/v1/#{@apiName}/#{@className}/#{methodName}.json"

    getObjectsFromResponse: (response)=>
        response?.response?[@className] or []

    show: (searchCondition)->
        searchCondition.classname or= @className
        super(searchCondition)

    query: (searchCondition)=>
        searchCondition.classname or= @className

        super(searchCondition)


module.exports = CustomObjects