Brainf*ck Interpreter

brainfuck.coffee

###
brainfuck() function
description: takes a string of Brainfuck code and returns the parsed result
usage: brainfuck('++++++++++[>+++++++>++++++++++>+++>+<<<<-]>++.>+.+++++++..+++.>++.<<+++++++++++++++.>.+++.------.--------.>+.>.')
       // output: 'Hello World.'
###

brainfuck = (code) ->
  inp = '23\n'
  out = ''
  codeSize = code.length
  i = 0
  ip = 0
  cp = 0
  dp = 0
  m = {}
  loopIn = {}
  loopOut = {}
  tmp = []
  cp = 0

  while cp < codeSize
    if code[cp] is '[' then tmp.push cp
    else loopOut[loopIn[cp] = tmp.pop()] = cp if code[cp] is ']'
    cp++
  cp = 0

  while cp < codeSize and i < 100000
    switch code[cp]
      when '>' then dp++
      when '<' then dp--
      when '+' then m[dp] = ((m[dp] or 0) + 1) & 255
      when '-' then m[dp] = ((m[dp] or 0) - 1) & 255
      when '.' then out += String.fromCharCode(m[dp])
      when ',' then m[dp] = inp.charCodeAt(ip++) or 0
      when '[' then m[dp] or (cp = loopOut[cp])
      when ']' then cp = loopIn[cp] - 1
    cp++
    i++

  return out