Specular.FRP.DVar.purs

module Specular.FRP.DVar
  ( DVar
  , new
  , read
  , value
  , modify_
  ) where

import Prelude

import Control.Monad.Cleanup (runCleanupT)
import Data.Tuple (fst)
import Effect.Class (class MonadEffect, liftEffect)
import Effect.Uncurried (EffectFn1, mkEffectFn1, runEffectFn1)
import Specular.FRP (Dynamic, current, foldDyn, newEvent, pull)
import Specular.FRP.Base (readBehavior)

data DVar a = DVar (Dynamic a) (EffectFn1 (a -> a) Unit)

new :: forall m a. MonadEffect m => a -> m (DVar a)
new initial = do
  -- Note: It's morally correct here to ignore cleanup action,
  -- because we're not subscribing to any outside events.
  --
  -- It will interact badly with the leak checker, but there's no easy
  -- solution atm.
  map fst $ runCleanupT do
    update <- newEvent
    dyn <- foldDyn ($) initial update.event
    pure (DVar dyn (mkEffectFn1 update.fire))

read :: forall m a. MonadEffect m => DVar a -> m a
read (DVar dyn _) = pull $ readBehavior $ current dyn

value :: forall a. DVar a -> Dynamic a
value (DVar dyn _) = dyn

modify_ :: forall m a. MonadEffect m => (a -> a) -> DVar a -> m Unit
modify_ f (DVar _ modify) = liftEffect $ runEffectFn1 modify f