default.nix

{ stdenv, lib, autoPatchelfHook, fetchzip, libunwind, libuuid, icu, curl
, darwin, makeWrapper, less, openssl_1_1, pam, lttng-ust }:

let archString = if stdenv.isAarch64 then "arm64"
                 else if stdenv.isx86_64 then "x64"
                 else throw "unsupported platform";
    platformString = if stdenv.isDarwin then "osx"
                     else if stdenv.isLinux then "linux"
                     else throw "unsupported platform";
    platformSha = if stdenv.isDarwin then "0w44ws8b6zfixf7xz93hmplqsx18279n9x8j77y4rbzs13fldvsn"
                     else if (stdenv.isLinux && stdenv.isx86_64) then "0xm7l49zhkz2fly3d751kjd5cy3ws9zji9i0061lkd06dvkch7jy"
                     else if (stdenv.isLinux && stdenv.isAarch64) then "18mlndncm5w6hrcfn1sk5zk026pzj16whg7dyb6k4wmxxdkb3v5l"
                     else throw "unsupported platform";
    platformLdLibraryPath = if stdenv.isDarwin then "DYLD_FALLBACK_LIBRARY_PATH"
                     else if stdenv.isLinux then "LD_LIBRARY_PATH"
                     else throw "unsupported platform";
                     libraries = [ libunwind libuuid icu curl openssl_1_1 ] ++
                       (if stdenv.isLinux then [ pam lttng-ust ] else [ darwin.Libsystem ]);
in
stdenv.mkDerivation rec {
  pname = "powershell";
  version = "7.1.3";

  src = fetchzip {
    url = "https://github.com/PowerShell/PowerShell/releases/download/v${version}/powershell-${version}-${platformString}-${archString}.tar.gz";
    sha256 = platformSha;
    stripRoot = false;
  };

  buildInputs = [ less ] ++ libraries;
  nativeBuildInputs = [ autoPatchelfHook makeWrapper ];

  installPhase =
  let
    ext = stdenv.hostPlatform.extensions.sharedLibrary;
  in ''
    pslibs=$out/share/powershell
    mkdir -p $pslibs

    cp -r * $pslibs

    rm -f $pslibs/libcrypto${ext}.1.0.0
    rm -f $pslibs/libssl${ext}.1.0.0

    # At least the 7.1.3-osx package does not have the executable bit set.
    chmod a+x $pslibs/pwsh

    ls $pslibs
  '' + lib.optionalString (!stdenv.isDarwin) ''
    patchelf --replace-needed libcrypto${ext}.1.0.0 libcrypto${ext}.1.1 $pslibs/libmi.so
    patchelf --replace-needed libssl${ext}.1.0.0 libssl${ext}.1.1 $pslibs/libmi.so
  '' + ''

    mkdir -p $out/bin

    makeWrapper $pslibs/pwsh $out/bin/pwsh \
      --prefix ${platformLdLibraryPath} : "${lib.makeLibraryPath libraries}" \
      --set TERM xterm --set POWERSHELL_TELEMETRY_OPTOUT 1 --set DOTNET_CLI_TELEMETRY_OPTOUT 1
  '';

  dontStrip = true;

  doInstallCheck = true;
  installCheckPhase = ''
    # May need a writable home, seen on Darwin.
    HOME=$TMP $out/bin/pwsh --help > /dev/null
  '';

  meta = with lib; {
    description = "Powerful cross-platform (Windows, Linux, and macOS) shell and scripting language based on .NET";
    homepage = "https://github.com/PowerShell/PowerShell";
    maintainers = with maintainers; [ yrashk srgom ];
    platforms = [ "x86_64-darwin" "x86_64-linux" "aarch64-linux"];
    license = with licenses; [ mit ];
  };

  passthru = {
    shellPath = "/bin/pwsh";
  };

}

gistfile1.txt

[alc@rpi4:~/nixpkgs]$ nix-build -A powershell
these derivations will be built:
  /nix/store/hljzf7bfrm357j972d8g89mxlf6qfqbk-source.drv
  /nix/store/nlwcl8vcgikzr9kgcnsfyxyl4bw9qh05-powershell-7.1.3.drv
building '/nix/store/hljzf7bfrm357j972d8g89mxlf6qfqbk-source.drv'...

trying https://github.com/PowerShell/PowerShell/releases/download/v7.1.3/powershell-7.1.3-linux-arm64.tar.gz
  % Total    % Received % Xferd  Average Speed   Time    Time     Time  Current
                                 Dload  Upload   Total   Spent    Left  Speed
100   641  100   641    0     0   5386      0 --:--:-- --:--:-- --:--:--  5386
100 60.8M  100 60.8M    0     0  19.0M      0  0:00:03  0:00:03 --:--:-- 20.5M
unpacking source archive /build/powershell-7.1.3-linux-arm64.tar.gz
hash mismatch in fixed-output derivation '/nix/store/as2c6jwzk2vwnrqjbybfrrf0dhb1sslq-source':
  wanted: sha256:18mlndncm5w6hrcfn1sk5zk026pzj16whg7dyb6k4wmxxdkb3v5l
  got:    sha256:1axbi4kmb1ydys7c45jhp729w1srid3c8jgivb4bdmdp56rf6h32
cannot build derivation '/nix/store/nlwcl8vcgikzr9kgcnsfyxyl4bw9qh05-powershell-7.1.3.drv': 1 dependencies couldn't be built
error: build of '/nix/store/nlwcl8vcgikzr9kgcnsfyxyl4bw9qh05-powershell-7.1.3.drv' failed