LoginLogicUnitTest.groovy

class LoginLogicUnitTest extends Specification {

  private CandidateLoginLogic logic

  def setup(){
    logic = new CandidateLoginLogic()
    
    // Mocking autowired methods
    OriginalTimeManager timeManager = Mock()
    logic.metaClass.setAttribute(logic, "timeManager", timeManager)
  }
    
  @Unroll
  def "IsAfterServiceGraduateDate currentDate: #currentDate"() {
    setup:
    // stubbing mocked test's retun value
    logic.timeManager.getCurrentLocalDate() >> currentDate
    
    when:
    def result = logic.isAfterServiceGraduateDate(graduateYear)
    
    then:
    result == flg
    
    where:
    // In this case the test are executed three times
    // Every tests are executed with the assigned values below
    currentDate               | graduateYear | flg
    LocalDate.of(2018, 3, 31) | 2018         | false
    LocalDate.of(2018, 4, 1)  | 2018         | true
    LocalDate.of(2018, 4, 2)  | 2018         | true
  }
    
  def "isAfterServiceGraduateDate NullPointerException throwability"() {
    setup:
    logic.timeManager.getCurrentLocalDate() >> LocalDate.of(2018, 4, 2)
    
    when:
    logic.isAfterServiceGraduateDate(null)
    
    then:
    thrown NullPointerException
  }
}