Removed erroneous trigger

selfdetectinghelper.st

;================================================================================
; ------- The mighty self-detecting Helper --------
;===============================================================================
[Statedef 10391]
anim = 1
ctrl = 0

[State 10391, lowest ID]
type = VelSet
trigger1 = !prevStateNo
x = ID - 50

[State 10391, P4]
type = VarSet
trigger1 = !time && !sysvar(2)
trigger1 = sysvar(0)
trigger1 = PlayerIDExist(floor(Vel X))
trigger1 = PlayerID(floor(Vel X)),IsHelper(10391)
trigger1 = PlayerID(sysvar(0)),NumPartner
trigger1 = PlayerID(floor(Vel X)),IsHomeTeam != IsHomeTeam
sysvar(2) = floor(Vel X)

[State 10391, P3]
type = VarSet
trigger1 = !time && !sysvar(1)
trigger1 = NumPartner
trigger1 = PlayerIDExist(floor(Vel X))
trigger1 = ID != floor(Vel X)
trigger1 = PlayerID(floor(Vel X)),IsHelper(10391)
trigger1 = PlayerID(floor(Vel X)),IsHomeTeam = IsHomeTeam
sysvar(1) = floor(Vel X)

[State 10391, P2]
type = VarSet
trigger1 = !time && !sysvar(0)
trigger1 = PlayerIDExist(floor(Vel X))
trigger1 = PlayerID(floor(Vel X)),IsHelper(10391)
trigger1 = PlayerID(floor(Vel X)),IsHomeTeam != IsHomeTeam
sysvar(0) = floor(Vel X)

[State 10391, Increment Loop]
type = VelAdd
trigger1 = !time
x = 1

[State 10391, ChangeState]
type = ChangeState
trigger1 = !time
trigger1 = sysvar(0)
trigger1 = cond(((PlayerID(sysvar(0)),NumPartner)),sysvar(2),1)
trigger1 = cond(NumPartner,sysvar(1),1)
value = stateno+1

[State 10391, ChangeState]
type = ChangeState
trigger1 = !time
trigger1 = floor(Vel X) < 2500
value = stateno

[State 10391, DestroySelf]
type = ChangeState
trigger1 = floor(Vel X) >= 2500
value = stateno+2
;---------------------------------------------------------------------
;All the standards can be coded here. 
;Vel X     - Used to perform the loops.
;sysvar(1) - Stores the ID of the copy of this helper in P2. 
; This is a work in progress** Detection of this helper still needs to be done for Players 3 and 4.
[Statedef 10392]
anim = 1
ctrl = 0

[State 10392, DisplayToClipboard]
type = DisplayToClipboard
trigger1 = PlayerIDExist(sysvar(0))
trigger1 = time%192 < 64
text = "loop = %d This helper is PlayerID = %d in P2"
params = floor(Vel X),sysvar(0)

[State 10392, DisplayToClipboard]
type = DisplayToClipboard
trigger1 = PlayerIDExist(sysvar(1))
trigger1 = time%192 = [64,127]
text = "loop = %d This helper is PlayerID = %d in My Partner"
params = floor(Vel X),sysvar(1)

[State 10392, DisplayToClipboard]
type = DisplayToClipboard
trigger1 = PlayerIDExist(sysvar(2))
trigger1 = time%192 > 127
text = "loop = %d This helper is PlayerID = %d in Their Partner"
params = floor(Vel X),sysvar(2)

;---------------------------------------------------------------------
;Stand by (detection failed) state.
[Statedef 10393]
anim = 1
ctrl = 0

[State 10392, DisplayToClipboard]
type = DisplayToClipboard
trigger1 = time >= 0
text = "No detection made. Diagnostics: sysvar(0) = %d sysvar(1) = %d sysvar(2) = %d"
params = sysvar(0), sysvar(1), sysvar(2)