https://www.mixmods.com.br/2020/09/ebisu-minami-pista-de-drift.html

Ebisu Minami.sc

// By Junior_Djjr - MixMods.com.br
// You can edit it to your map mods, just keep clear credits to me.
// You need: https://forum.mixmods.com.br/f16-utilidades/t179-gta3script-while-true-return_true-e-return_false
SCRIPT_START
{
    LVAR_INT scplayer hVeh
    
    GET_PLAYER_CHAR 0 scplayer

    // Faster testing
    //WAIT 500
    //SET_CHAR_COORDINATES_NO_OFFSET scplayer -2757.8 195.6308 6.9043

    WHILE TRUE
        WAIT 0
        
        WHILE LOCATE_CHAR_ANY_MEANS_3D scplayer -2750.0168 202.7279 7.0501 150.0 150.0 150.0 FALSE
            WAIT 0

            IF LOCATE_STOPPED_CHAR_IN_CAR_3D scplayer -2750.0168 202.7279 7.0501 3.0 3.0 3.0 TRUE
                IF IS_CHAR_SITTING_IN_ANY_CAR scplayer
                    STORE_CAR_CHAR_IS_IN_NO_SAVE scplayer hVeh

                    SET_PLAYER_CONTROL 0 OFF
                    DO_FADE 1000 0 
                    WAIT 1000
                    
                    SET_CAR_COORDINATES_NO_OFFSET hVeh 807.1569 84.3655 1011.3605
                    SET_CAR_HEADING hVeh 289.7109

                    // same number fom IPL file
                    SET_VEHICLE_AREA_VISIBLE hVeh 1 //if can't compile this line, open your commands.xml file from GTA3script compiler, find it and remove that Out="true"
                    SET_CHAR_AREA_VISIBLE scplayer 1
                    SET_AREA_VISIBLE 1

                    WAIT 1000
                    RESTORE_CAMERA_JUMPCUT
                    DO_FADE 1500 1 
                    SET_PLAYER_CONTROL 0 ON
                    
                    WHILE LOCATE_CHAR_ANY_MEANS_3D scplayer 800.4977 81.444 1012.4877 1000.0 1000.0 400.0 FALSE
                        WAIT 0

                        IF LOCATE_CHAR_ANY_MEANS_3D scplayer 793.4788 78.7037 1012.8449 3.0 3.0 3.0 TRUE

                            SET_PLAYER_CONTROL 0 OFF
                            DO_FADE 1000 0 
                            WAIT 1000

                            IF IS_CHAR_SITTING_IN_ANY_CAR scplayer
                                STORE_CAR_CHAR_IS_IN_NO_SAVE scplayer hVeh
                                SET_CAR_COORDINATES_NO_OFFSET hVeh -2750.0168 202.7279 7.0501
                                SET_CAR_HEADING hVeh 0.0
                            ELSE
                                SET_CHAR_COORDINATES_NO_OFFSET scplayer -2750.0168 202.7279 7.0501
                                SET_CHAR_HEADING scplayer 0.0
                            ENDIF
                            SET_VEHICLE_AREA_VISIBLE hVeh 0
                            SET_CHAR_AREA_VISIBLE scplayer 0
                            SET_AREA_VISIBLE 0

                            WAIT 1000
                            RESTORE_CAMERA_JUMPCUT
                            DO_FADE 1500 1 
                            SET_PLAYER_CONTROL 0 ON

                            WHILE LOCATE_CHAR_ANY_MEANS_3D scplayer -2750.0168 202.7279 7.0501 3.0 3.0 3.0 FALSE
                                WAIT 0
                            ENDWHILE

                            BREAK

                        ENDIF

                    ENDWHILE
                ELSE
                    PRINT_STRING_NOW "You need a car!" 100
                ENDIF
            ENDIF

        ENDWHILE

    ENDWHILE
}
SCRIPT_END