https://www.mixmods.com.br/2022/03/sa-damage-screen-blood/

Damage Screen Blood (Junior_Djjr).sc

// by Junior_Djjr
// You need: https://forum.mixmods.com.br/f141-gta3script-cleo/t5206-como-criar-scripts-com-cleoplus
SCRIPT_START
{
    LVAR_INT scplayer hChar pEntity iType iPiece i pUseSprite scplayer2 pScreen1 pScreen2
    LVAR_FLOAT fIntensity fCurScreenBlood fMaxOpacity fIncrease fDecrease

    IF NOT READ_FLOAT_FROM_INI_FILE "CLEO\Damage Screen Blood.ini" "Settings" "MaxOpacity" (fMaxOpacity)
        fMaxOpacity = 255.0
    ENDIF
    IF NOT READ_FLOAT_FROM_INI_FILE "CLEO\Damage Screen Blood.ini" "Settings" "Increase" (fIncrease)
        fIncrease = 6.0
    ENDIF
    IF NOT READ_FLOAT_FROM_INI_FILE "CLEO\Damage Screen Blood.ini" "Settings" "Decrease" (fDecrease)
        fDecrease = 0.8
    ENDIF

    LOAD_TEXTURE_DICTIONARY scrnbld
    LOAD_SPRITE 1 screenblood1
    LOAD_SPRITE 2 screenblood2
    GET_TEXTURE_FROM_SPRITE 1 pScreen1
    GET_TEXTURE_FROM_SPRITE 2 pScreen2

    GET_PLAYER_CHAR 0 (scplayer)

    SET_SCRIPT_EVENT_CHAR_DAMAGE ON OnCharDamage hChar

    pUseSprite = pScreen1

    WHILE TRUE
        WAIT 0
        IF fCurScreenBlood > 0.0
            i =# fCurScreenBlood
            DRAW_TEXTURE_PLUS pUseSprite DRAW_EVENT_BEFORE_HUD (320.0 224.0 -640.0 448.0) 0.0 0.0 FALSE 0 0 (255 255 255 i)
            fCurScreenBlood -=@ fDecrease
            IF fCurScreenBlood <= 0.0
                fCurScreenBlood = 0.0
                pUseSprite = pScreen1
            ENDIF
        ENDIF
        IF IS_2PLAYER_GAME_GOING_ON
            GET_PLAYER_CHAR 1 (scplayer2)
        ELSE
            scplayer2 = -1
        ENDIF
        //PRINT_FORMATTED_NOW "%f" 1000 fCurScreenBlood
    ENDWHILE

    OnCharDamage:
    IF hChar = scplayer
        OnCharDamage_Increase:
        GET_CHAR_DAMAGE_LAST_FRAME hChar pEntity iType iPiece fIntensity
        IF fIntensity > 40.0
            pUseSprite = pScreen2
        ENDIF
        fIntensity *= fIncrease
        fCurScreenBlood += fIntensity
        CLAMP_FLOAT fCurScreenBlood 0.0 fMaxOpacity (fCurScreenBlood)
    ELSE
        IF IS_2PLAYER_GAME_GOING_ON
            IF hChar = scplayer2
                GOTO OnCharDamage_Increase
            ENDIF
        ENDIF
    ENDIF
    RETURN_SCRIPT_EVENT

}
SCRIPT_END