https://www.mixmods.com.br/2019/09/estrela-por-dirigir-veiculos-de.html

Star for driving authority vehicles (Junior_Djjr).sc

// by Junior_Djjr - MixMods.com.br
// You need: https://forum.mixmods.com.br/f16-utilidades/t179-gta3script-while-true-return_true-e-return_false
SCRIPT_START
{
    LVAR_INT scplayer playerId veh char pedType vehModel playerModel level levelGreaterThan ignoreClosedVehicles ignoreCopOutfit
    LVAR_FLOAT x y z speed radius

    IF NOT READ_INT_FROM_INI_FILE "CLEO/Star for driving authority vehicles.ini" "Settings" "IgnoreClosedVehicles" (ignoreClosedVehicles)
        ignoreClosedVehicles = TRUE
    ENDIF
    IF NOT READ_INT_FROM_INI_FILE "CLEO/Star for driving authority vehicles.ini" "Settings" "IgnoreCopOutfit" (ignoreCopOutfit)
        ignoreCopOutfit = TRUE
    ENDIF

    WHILE TRUE
        WAIT 2100
        
        playerId = 0
        GOSUB Run

        IF IS_2PLAYER_GAME_GOING_ON
            playerId = 1
            GOSUB Run
        ENDIF

    ENDWHILE

    Run:
    GET_PLAYER_CHAR playerId (scplayer)
    IF IS_CHAR_SITTING_IN_ANY_CAR scplayer
        STORE_CAR_CHAR_IS_IN_NO_SAVE scplayer (veh)
        GET_CAR_MODEL veh vehModel
        IF ignoreClosedVehicles = TRUE
            IF vehModel = RHINO
            OR vehModel = SWATVAN
                RETURN
            ENDIF
        ENDIF
        IF IS_EMERGENCY_SERVICES_VEHICLE veh
            GOSUB Check
        ELSE
            IF vehModel = HUNTER
            OR vehModel = HYDRA
                GOSUB Check
            ENDIF
        ENDIF
    ENDIF
    RETURN

    Check:
    IF vehModel = RHINO
    OR vehModel = HUNTER
    OR vehModel = HYDRA
        level = 4
    ELSE
        level = 2
    ENDIF
    levelGreaterThan = level - 1
    IF IS_WANTED_LEVEL_GREATER playerId levelGreaterThan
        RETURN
    ENDIF
    GET_CAR_SPEED veh speed
    speed /= 2.0
    radius = 30.0 - speed
    IF radius < 10.0
        RETURN
    ENDIF
    IF ignoreCopOutfit = TRUE
        GET_CHAR_MODEL scplayer playerModel
        IF playerModel = 0
            IF IS_PLAYER_WEARING playerId 17 POLICETR
                RETURN
            ENDIF
        ELSE
            IF playerModel >= 280
            AND playerModel <= 284
                RETURN
            ENDIF
        ENDIF
    ENDIF
    GET_CHAR_COORDINATES scplayer x y z
    IF GET_RANDOM_CHAR_IN_SPHERE_NO_SAVE_RECURSIVE x y z radius FALSE TRUE (char)
        GOSUB CheckCop
        WHILE GET_RANDOM_CHAR_IN_SPHERE_NO_SAVE_RECURSIVE x y z radius TRUE TRUE (char)
            GOSUB CheckCop
        ENDWHILE
    ENDIF
    RETURN

    CheckCop:
    GET_PED_TYPE char pedType
    IF NOT pedType = 6
        RETURN
    ENDIF
    IF NOT HAS_CHAR_SPOTTED_CHAR_IN_FRONT char scplayer
        RETURN
    ENDIF
    ALTER_WANTED_LEVEL_NO_DROP playerId level
    RETURN

}
SCRIPT_END