Movement Detector Device in Verse for UEFN

movement_detector_device.verse

using { /Verse.org/Simulation }
using { /UnrealEngine.com/Temporary/SpatialMath }

using { /Fortnite.com/Devices }
using { /Fortnite.com/Characters }

movement_detector_device := class(creative_device):

    @editable
    MinimumMovementDistance : float = 100.0

    OnBegin<override>()<suspends>:void = 
        for(Player : GetPlayspace().GetPlayers()):
            OnPlayerAdded(Player)
        GetPlayspace().PlayerAddedEvent().Subscribe(OnPlayerAdded)

    OnPlayerAdded<private>(Player : player):void =
        spawn { CheckForMovement(Player) }

    CheckForMovement<private>(Player : player)<suspends>:void = 
        if(FortChar := Player.GetFortCharacter[]):
            var OldPos : vector3 = FortChar.GetTransform().Translation
            loop:
                NewPos := FortChar.GetTransform().Translation
                Dist := Distance(NewPos,OldPos)
                if(Dist > MinimumMovementDistance):
                    set OldPos = NewPos
                    HandlePlayerMoved(Player)
                Sleep(0.1)
                if(not GetPlayspace().GetPlayers().Find[Player]) then break #player was removed

    HandlePlayerMoved(Player : player) : void =
        Print("Player Moved!")